;;; Vikalpa --- Proof Assistant
;;; Copyright © 2020 Masaya Tojo <masaya@tojo.tokyo>
;;;
;;; This file is part of Vikalpa.
;;;
;;; Vikalpa is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or
;;; (at your option) any later version.
;;;
;;; Vikalpa is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
;;; General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with Vikalpa.  If not, see <http://www.gnu.org/licenses/>.

(define-module (vikalpa)
  #:export (rewrite
            show
            check
            system->scheme
            load-system
            system-primitives
            system-functions
            system-macros
            system-theorems
            system-axioms
            system-totality-claims
            define-system
            define-axiom
            define-theorem
            define-primitive-function
            define-function
            define-proof
            define-totality-claim
            define-syntax-rules
            succ
            pred)
  #:use-module (ice-9 match)
  #:use-module (ice-9 format)
  #:use-module (ice-9 control)
  #:use-module ((srfi srfi-1)
                #:select (every any member lset-union fold append-map))
  #:use-module (srfi srfi-8)
  #:use-module (srfi srfi-11)
  #:use-module (srfi srfi-26)
  #:use-module (ice-9 pretty-print))

(define (debug f . args)
  (if #f
      (apply format #t f args)
      #t))

(define-syntax-rule (define/guard (name (var pred?) ...) b b* ...)
  (define (name var ...)
    (unless (pred? var)
      (error (format #f
                     "~a:~%  expected:  ~a~%  given: "
                     'name
                     'pred?)
             var))
    ...
    b b* ...))

;; (natural? x) -> boolean?
(define (natural? x)
  (and (exact-integer? x)
       (not (negative? x))))

(define (option p?)
  (lambda (x)
    (or (p? x) (not x))))

(define (list-of p?)
  (lambda (x)
    (and (list? x)
         (every p? x))))

;; (expression? x) -> boolean?
(define (expression? expr)
  (cond ((expr-quoted? expr)
         (or (natural? (expr-unquote expr))
             (boolean? (expr-unquote expr))
             (symbol? (expr-unquote expr))
             (null? (expr-unquote expr))))
        ((if-form? expr)
         (and (expression? (if-form-test expr))
              (expression? (if-form-then expr))
              (expression? (if-form-else expr))))
        ((app-form? expr)
         (and (symbol? (car expr))
              (list? (cdr expr))
              (every expression? (cdr expr))))
        ((variable? expr) #t)
        (else #f)))

(define (app-form? expr)
  (and (pair? expr)
       (not (eq? (car expr) 'quote))
       (not (eq? (car expr) 'if))))

(define (app-form-name expr)
  (car expr))

(define (app-form-args expr)
  (cdr expr))

(define (if-form test then else)
  (list 'if test then else))

(define (if-form? x)
  (and (pair? x)
       (eq? (car x) 'if)))

(define (if-form-test expr)
  (list-ref expr 1))

(define (if-form-then expr)
  (list-ref expr 2))

(define (if-form-else expr)
  (list-ref expr 3))

(define (expression-functions expr)
  (cond
   ((if-form? expr)
    (apply lset-union
           eq?
           (map expression-functions
                (list (if-form-test expr)
                      (if-form-then expr)
                      (if-form-else expr)))))
   ((app-form? expr)
    (cons (app-form-name expr)
          (apply lset-union
                 eq?
                 (map expression-functions (app-form-args expr)))))
   (else '())))

(define (expression-vars expr)
  (cond
   ((app-form? expr)
    (apply lset-union eq?
           (map expression-vars (app-form-args expr))))
   ((variable? expr) (list expr))
   (else '())))

;; (expr-quoted? x) -> boolean?
(define (expr-quoted? expr)
  (and (pair? expr)
       (eq? 'quote (car expr))
       (pair? (cdr expr))
       ((const #t) (car (cdr expr)))
       (null? (cdr (cdr expr)))))

(define (expr-unquote expr)
  (car (cdr expr)))

;; (expr-quoted? x) -> boolean?
(define (expr-quote expr)
  (list 'quote expr))

;; (variable? x) -> boolean?
(define (variable? x)
  (symbol? x))

;; (variable=? variable? variable?) -> boolean?
(define (variable=? v1 v2)
  (eq? v1 v2))

;; (rule? x) -> boolean?
(define (rule? x)
  (and (list? x)
       (= 5 (length x))
       (eq? (car x) 'rule)
       (let ((vars (list-ref x 1)))
         (and (list? vars)
              (every variable? vars)))
       (let ((preconds (list-ref x 2)))
         (and (list? preconds)
              (every expression? preconds)))
       (expression? (list-ref x 3))
       (expression? (list-ref x 4))))

;; (rule (list-of variable?) expression? expression?) -> rule?
(define (rule vars preconds lhs rhs)
  (list 'rule vars preconds lhs rhs))

;; (rule-vars rule?) -> (list-of variable?)
(define (rule-vars r)
  (list-ref r 1))

;; (rule-preconds rule?) -> expression?
(define (rule-preconds r)
  (list-ref r 2))

;; (rule-lhs rule?) -> expression?
(define (rule-lhs r)
  (list-ref r 3))

;; (rule-rhs rule?) -> expression?
(define (rule-rhs r)
  (list-ref r 4))

(define (binding? x)
  (and (pair? x)
       (symbol? (car x))
       (expression? (cdr x))))

(define (env? x)
  ((list-of binding?) x))

(define/guard (substitute (env env?) (expr (const #t)))
  (debug "substitute: ~s ~s~%" env expr)
  (cond ((expr-quoted? expr) expr)
        ((pair? expr)
         (cons (substitute env (car expr))
               (substitute env (cdr expr))))
        ((assoc expr env) => cdr)
        (else expr)))

(define (match-rule preconds rl expr env)
  (define (fail)
    (shift k #f))
  (define (var? v)
    (and (member v (rule-vars rl))
         #t))
  (define (add-env var expr env)
    (cond
     ((assoc var env)
      => (match-lambda
           ((env-var . env-expr)
            (if (equal? env-expr expr)
                env
                (fail)))))
     (else
      (cons (cons var expr)
            env))))
  (define (mat-fold lhss exprs env)
    (cond ((and (pair? lhss) (pair? exprs))
           (mat-fold (cdr lhss)
                     (cdr exprs)
                     (mat (car lhss)
                          (car exprs)
                          env)))
          ((and (null? lhss) (null? exprs)) env)
          (else (fail))))
  (define (mat-begin lhs expr env)
    (reset (mat lhs expr env)))
  (define (mat lhs expr env)
    (debug "lhs ~a, expr ~a, env ~a~%" lhs expr env)
    (cond ((expr-quoted? lhs)
           (if (expr-quoted? expr)
               (if (equal? lhs expr)
                   env
                   (fail))
               (fail)))
          ((and (if-form? lhs)
                (if-form? expr))
           (mat-fold (list (if-form-test lhs)
                           (if-form-then lhs)
                           (if-form-else lhs))
                     (list (if-form-test expr)
                           (if-form-then expr)
                           (if-form-else expr))
                     env))
          ((app-form? lhs)
           (if (and (app-form? expr)
                    (symbol? (app-form-name lhs))
                    (eqv? (app-form-name lhs) (app-form-name expr)))
               (mat-fold (app-form-args lhs) (app-form-args expr) env)
               (fail)))
          ((var? lhs) (add-env lhs expr env))
          (else (fail))))
  (define (mat-preconds rlps k+env)
    (if (null? rlps)
        k+env
        (mat-preconds
         (cdr rlps)
         (let search ((ps preconds))
           (when (equal? rl '(rule (x y) ((natural? y) (natural? x)) (quote #t) (natural? (+ x y))))
             (format #t "search~% rl: ~s~% rlps: ~s~% ps: ~s~% env: ~s~%" rl rlps ps (cdr k+env)))
           (if (null? ps)
               ((car k+env) #f)
               (let ((env (mat-begin (car rlps) (car ps) (cdr k+env))))
                 (cond
                  ((mat-begin (car rlps) (car ps) (cdr k+env))
                   => (lambda (env)
                        (shift k0
                               (reset (or (shift k (k0 (cons k env)))
                                          (k0 (search (cdr ps))))))))
                  (else (search (cdr ps))))))))))
  (define (valid? env expr)
    (cond ((expr-quoted? expr) #t)
          ((pair? expr)
           (and (valid? env (car expr))
                (valid? env (cdr expr))))
          ((var? expr)
           (cond ((assoc expr env) => (const #t))
                 (else #f)))
          (else #t)))
  (debug "rule: ~a~%" rl)
  (debug "preconds: ~a~%" preconds)
  (debug "expr: ~a~%" expr)
  (reset
   (shift k0
          (match (mat-preconds (rule-preconds rl) (cons k0 env))
            ((k . env)
             (cond
              ((mat-begin (rule-lhs rl) expr env)
               => (lambda (env)
                    (if (valid? env (rule-rhs rl))
                        env
                        (k #f))))
              (else (k #f))))
            (else #f)))))

;; (apply-rule preconds rule? expression?) -> (or (cons rhs env?) #f)
(define (apply-rule preconds rl expr env)
  (cond
   ((match-rule preconds rl expr env)
    => (cut substitute <> (rule-rhs rl)))
   (else #f)))


(define (system? x)
  (and (list? x)
       (= 4 (length x))
       (eq? 'system (list-ref x 0))
       (system-definitions? (system-definitions x))
       (system-proofs? (system-proofs x))
       ((const #t) (system-totality-claim-list x))))

(define (make-system defs prfs totality-claims)
  (list 'system defs prfs totality-claims))

(define (system-definitions sys)
  (list-ref sys 1))

(define (system-proofs sys)
  (list-ref sys 2))

(define (system-totality-claim-list sys)
  (list-ref sys 3))

(define (totality-claim id nat? less-than)
  (list id nat? less-than))

(define (totality-claim-id x)
  (list-ref x 0))

(define (totality-claim-natural x)
  (list-ref x 1))

(define (totality-claim-less-than x)
  (list-ref x 2))

(define (lookup x sys)
  (assoc x (system-definitions sys)))

(define (find-proof x sys)
  (assoc x (system-proofs sys)))

;; (system-definitions? x) -> boolean?
(define (system-definitions? x)
  (cond ((null? x) #t)
        ((pair? x)
         (and (pair? (car x))
              (or (theorem*? (car x))
                  (primitive-function? (car x))
                  (macro? (car x))
                  (function? (car x)))
              (system-definitions? (cdr x))))
        (else #f)))

;; (system-proofs? x) -> boolean?
(define (system-proofs? x)
  (cond ((null? x) #t)
        ((pair? x)
         (and (pair? (car x))
              (proof? (car x))
              (system-proofs? (cdr x))))
        (else #f)))

(define (primitive-function? x)
  (and (list? x)
       (= 3 (length x))
       (variable? (primitive-function-name x))
       (eq? 'primitive-function (list-ref x 1))
       (vars? (primitive-function-vars x))))

;; (primitive-function variable? vars?) -> primitive-function?
(define (primitive-function name vs)
  (list name 'primitive-function vs))

(define (primitive-function-name pf)
  (list-ref pf 0))

(define (primitive-function-vars pf)
  (list-ref pf 2))

(define (function? x)
  (and (list? x)
       (= 6 (length x))
       (variable? (function-name x))
       (eq? 'function (list-ref x 1))
       (vars? (function-vars x))
       (expression? (function-expression x))
       ((const #t) (function-code x))
       (boolean? (function-primitive? x))))

;; (function variable? vars? expression?) -> function?
(define/guard (function (name variable?)
                        (vars vars?)
                        (expr expression?)
                        (code (const #t))
                        (primitive boolean?))
  (list name 'function vars expr code primitive))

(define (function-name f)
  (list-ref f 0))

(define (function-vars f)
  (list-ref f 2))

(define (function-expression f)
  (list-ref f 3))

(define (function-code f)
  (list-ref f 4))

(define (function-primitive? f)
  (list-ref f 5))

(define (definition-name d)
  (list-ref d 0))

(define (definition-vars d)
  (list-ref d 2))

(define (definition-expression d)
  (list-ref d 3))

(define (mrule? x)
  (and (list? x)
       (= 3 (length x))
       (eq? 'mrule (list-ref x 0))
       ((const #t) (mrule-lhs x))
       ((const #t) (mrule-rhs x))))

(define (mrule lhs rhs)
  (list 'mrule lhs rhs))

(define (mrule-vars mrl)
  (define (all-vars x)
    (cond ((expr-quoted? x) '())
          ((pair? x)
           (append (all-vars (car x))
                   (all-vars (cdr x))))
          ((variable? x) (list x))
          (else '())))
  (all-vars (mrule-lhs mrl)))

(define (mrule-lhs mrl)
  (list-ref mrl 1))

(define (mrule-rhs mrl)
  (list-ref mrl 2))

(define (macro? x)
  (and (list? x)
       (= 4 (length x))
       (eq? 'macro (list-ref x 1))
       (variable? (macro-name x))
       (let ((mrls (macro-mrules x)))
         (and (list? mrls)
              (every mrule? mrls)))
       ((list-of symbol?) (macro-literals x))))

(define (macro-name m)
  (list-ref m 0))

(define (macro-mrules m)
  (list-ref m 2))

(define (macro-literals m)
  (list-ref m 3))

(define (macro name rules ls)
  (list name 'macro rules ls))

(define (apply-mrule rl ls expr)
  (define (literal? x)
    (member x ls))
  (define (var? v)
    (and (member v (mrule-vars rl))
         #t))
  (call/cc
   (lambda (k)
     (define (mat-map lhs-tree expr-tree env)
       (cond ((and (pair? lhs-tree)
                   (pair? expr-tree))
              (mat-map (car lhs-tree)
                       (car expr-tree)
                       (mat-map (cdr lhs-tree)
                                (cdr expr-tree)
                                env)))
             (else (mat lhs-tree expr-tree env))))
     (define (mat lhs expr env)
       (cond ((expr-quoted? lhs)
              (if (expr-quoted? expr)
                  (if (equal? lhs expr)
                      env
                      (k #f))
                  (k #f)))
             ((and (pair? lhs) (pair? expr))
              (mat-map lhs expr env))
             ((literal? lhs)
              (if (eq? lhs expr)
                  env
                  (k #f)))
             ((var? lhs)
              (cond
               ((assoc lhs env)
                => (match-lambda
                     ((env-var . env-expr)
                      (if (equal? env-expr expr)
                          env
                          (k #f)))))
               (else
                (cons (cons lhs expr)
                      env))))
             ((eqv? lhs expr) env)
             (else (k #f))))
     (define (mrule-substitute env expr)
       (cond ((expr-quoted? expr) expr)
             ((pair? expr)
              (cons (mrule-substitute env (car expr))
                    (mrule-substitute env (cdr expr))))
             ((literal? expr) expr)
             ((and (variable? expr) (assoc expr env)) => cdr)
             (else expr)))
     (mrule-substitute (mat (mrule-lhs rl)
                            expr
                            '())
                       (mrule-rhs rl)))))

(define (apply-macro m expr)
  (cond ((and (pair? expr)
              (eq? (macro-name m) (car expr)))
         (let loop ((rs (macro-mrules m)))
           (cond ((null? rs)
                  (error "(vikalpa) macro fail" m expr))
                 ((apply-mrule (car rs) (macro-literals m) expr) => identity)
                 (else (loop (cdr rs))))))
        (else #f)))

(define (expand ms expr)
  (let loop ((ms ms)
             (expr expr))
    (cond
     ((null? ms) expr)
     (else (expand (cdr ms)
                   (cond
                    ((apply-macro (car ms) expr) => identity)
                    (else expr)))))))

(define (expand* ms expr)
  (let loop ((ms ms)
             (expr expr))
    (let ((new-expr (expand ms expr)))
      (if (equal? expr new-expr)
          (if (pair? new-expr)
              (cons (expand* ms (car new-expr))
                    (expand* ms (cdr new-expr)))
              new-expr)
          (expand* ms new-expr)))))

(define (quote-all x)
  (cond
   ((null? x) x)
   ((expr-quoted? x) x)
   ((pair? x)
    (cons (quote-all (car x))
          (quote-all (cdr x))))
   ((symbol? x) x)
   (else `',x)))

(define (let? x)
  (and (list? x)
       (= 3 (length x))
       (eq? 'let (list-ref x 0))
       ((list-of (lambda (x)
                   (and (list? x)
                        (= 2 (length x))
                        (symbol? (car x))))) 
        (list-ref x 1))))

(define (expand-let x)
  (define (let-substitute env expr)
    (cond ((expr-quoted? expr) expr)
          ((let? expr)
           (let-substitute
            (append (map (lambda (binding)
                           (cons (car binding)
                                 (let-substitute env
                                                 (cadr binding))))
                         (list-ref expr 1))
                    env)
            (list-ref expr 2)))
          ((pair? expr)
           (cons (let-substitute env (car expr))
                 (let-substitute env (cdr expr))))
          ((assoc expr env) => cdr)
          (else expr)))
  (cond
   ((expr-quoted? x) x)
   ((let? x)
    (expand-let
     (let-substitute (map (lambda (binding) (cons (car binding)
                                                  (cadr binding)))
                          (list-ref x 1))
                     (list-ref x 2))))
   ((pair? x)
    (cons (expand-let (car x))
          (expand-let (cdr x))))
   (else x)))

(define (succ x)
  (+ x 1))

(define (pred x)
  (- x 1))

(define (natural->expr n)
  (if (<= n 0)
      ''0
      `(succ ,(natural->expr (pred n)))))

(define (pair->expr x)
  (if (pair? x)
      `(cons ,(pair->expr (car x))
             ,(pair->expr (cdr x)))
      (expr-quote x)))

(define (expand-quoted x)
  (cond
   ((expr-quoted? x)
    (let ((val (expr-unquote x)))
      (cond
       ((natural? val)
        (natural->expr val))
       ((pair? val)
        (pair->expr val))
       (else x))))
   ((pair? x)
    (cons (expand-quoted (car x))
          (expand-quoted (cdr x))))
   (else x)))

(define (convert-to-expression x)
  (expand-quoted
   (quote-all
    (expand* (filter macro? (system-definitions (current-system)))
             (expand-let x)))))

;; (axiom variable? vars? expression?) -> axiom?
;; axiom? is theorem*
(define/guard (axiom (name variable?) (vars vars?) (expr expression?))
  (list name 'axiom vars expr))

(define (vars? x)
  (and (list? x)
       (every variable? x)))

;; (axiom? x) -> boolean?
(define (axiom? x)
  (and (list? x)
       (= 4 (length x))
       (variable?  (list-ref x 0))
       (eq? 'axiom (list-ref x 1))
       (vars? (list-ref x 2))
       (expression? (list-ref x 3))))

;; (theorem name vars? expression?) -> theorem?
(define/guard (theorem (name variable?) (vars vars?) (expr expression?))
  (list name 'theorem vars expr))

;; (theorem? x) -> boolean?
;; theorem? is theorem*
(define (theorem? x)
  (and (list? x)
       (= 4 (length x))
       (variable? (list-ref x 0))
       (eq? 'theorem (list-ref x 1))
       (vars? (list-ref x 2))
       (expression? (list-ref x 3))))

(define (theorem-name x)
  (list-ref x 0))

;; (theorem*? x) -> boolean?
(define (theorem*? x)
  (or (axiom? x)
      (theorem? x)))

(define (theorem*-name x)
  (list-ref x 0))

(define (theorem*-vars x)
  (list-ref x 2))

(define (theorem*-expression x)
  (list-ref x 3))

(define (theorem*-rules x)
  (expression->rules (theorem*-vars x)
                     '()
                     (theorem*-expression x)))

;; (rewriter path? command?) -> rewriter?
(define (rewriter p c)
  (cons p c))

(define (rewriter-path r)
  (car r))

(define (rewriter-command r)
  (cdr r))

(define (rewriter? x)
  (and (pair? x)
       (path? (car x))
       (command? (cdr x))))

;; (sequence? x) -> boolean?
(define (sequence? x)
  (and (list? x)
       (every rewriter? x)))

;; (path? x) -> boolean?
;; path is list
(define (path? x)
  (and (list? x)
       (every natural? x)))

;; (command-name? x) -> booelan?
(define (command? x)
  (and (pair? x)
       (command-name? (car x))
       ((list-of command-option?) (cdr x))))

;; (command-name? x) -> booelan?
(define (command-name? x)
  (or (symbol? x)
      ((list-of symbol?) x)))

;; (command-option? x) -> boolean?
(define (command-option? x)
  (and (pair? x)
       (case (car x)
         ((set) (and (list? x)
                     (= 3 (length x))
                     (variable? (list-ref x 1))
                     (expression? (list-ref x 2))))
         (else #f))))

(define (command-name x)
  (car x))

(define (command-options x)
  (cdr x))

;; (extract path? expression? preconds? procedure?) -> (values expression? procedure?)
(define (extract path expr fail)
  (if (null? path)
      (values expr '() identity)
      (let ((i (car path)))
        (cond
         ((if-form? expr)
          (let ((precond (if-form-test expr)))
            (receive (extracted-expr extracted-preconds builder)
                (extract (cdr path) (list-ref expr i) fail)
              (values extracted-expr
                      (case i
                        ((1) '())
                        ((2) (cons (prop-not (prop-not precond))
                                   extracted-preconds))
                        ((3) (cons (prop-not precond) extracted-preconds))
                        (else (fail 'if-invaild-path path)))
                      (lambda (x)
                        (append (list-head expr i)
                                (list (builder x))
                                (list-tail expr (+ i 1))))))))
         ((< i (length expr))
          (receive (extracted-expr preconds builder)
              (extract (cdr path) (list-ref expr i) fail)
            (values extracted-expr
                    preconds
                    (lambda (x)
                      (append (list-head expr i)
                              (list (builder x))
                              (list-tail expr (+ i 1)))))))
         (else
          (fail 'invalid-path path))))))

(define (function->rules x)
  (list (rule (function-vars x)
              '()
              (function-app-form x)
              (function-expression x))
        (rule (function-vars x)
              '()
              (function-expression x)
              (function-app-form x))))

(define (apply-function f args)
  (apply-rule '()
              (rule (function-vars f)
                    '()
                    (function-app-form f)
                    (function-expression f))
              (cons (function-name f) args)
              '()))

(define (parse-options/theorem ops fail)
  (if (null? ops)
      (values '())
      (receive (env)
          (parse-options/theorem (cdr ops) fail)
        (case (caar ops)
          ((set) (let ((op (car ops)))
                   (cons (cons (list-ref op 1)
                               (list-ref op 2))
                         env)))
          (else
           (fail 'invalid-option (car ops)))))))

(define (rewrite/theorem cmd b thm preconds expr fail)
  (receive (env)
      (parse-options/theorem (command-options cmd) fail)
    (cond
     ((any (cut apply-rule preconds <> expr env)
           (theorem*-rules thm)) => identity)
     (else
      (fail 'apply-theorem cmd expr)))))

;; (rewrite system? rewriter? expression? procedure?) -> expr
(define (rewrite1 sys expr fail r)
  (let* ((cmd (rewriter-command r))
         (cmd/name (command-name cmd)))
    (debug "~%~%cmd: ~a~%" cmd)
    (receive (extracted-expr preconds builder)
        (extract (rewriter-path r) expr fail)
      (builder
       (cond
        ((eq? 'equal? cmd/name)
         (match extracted-expr
           (('equal? `(quote ,x) `(quote ,y))
            (expr-quote (equal? x y)))
           (else
            (fail 'equal? 'extracted-expr))))
        ((eq? 'error cmd/name) (fail extracted-expr))
        ((and (symbol? cmd/name)
              (lookup cmd/name sys))
         => (lambda (x)
              (cond
               ((theorem*? x)
                (rewrite/theorem cmd sys x preconds extracted-expr fail))
               ((function? x)
                (cond
                 ((any (cut apply-rule '() <> extracted-expr '())
                       (function->rules x)) => identity)
                 (else
                  (fail 'apply-function cmd extracted-expr))))
               (else
                (fail 'invalid-command cmd extracted-expr)))))
        (else (fail 'command-not-found cmd extracted-expr)))))))

(define/guard (rewrite (sys system?) (expr expression?) (seq sequence?))
  (debug "rewrite ~y~%" expr)
  (let loop ((expr expr)
             (seq seq))
    (debug "~y~%" expr)
    #;(format #t "~y~%" expr)
    (reset
     (if (null? seq)
         expr
         (loop (rewrite1 sys
                         expr
                         (lambda args
                           (shift k (cons 'error args)))
                         (car seq))
               (cdr seq))))))

(define (expr-not x)
  (list 'not x))

(define (prop-not x)
  (match x
    (('not ('not expr)) (prop-not expr))
    (('not expr) expr)
    (expr (expr-not expr))))

(define (expr-equal? x)
  (and (list? x)
       (= 3 (length x))
       (eq? 'equal? (list-ref x 0))
       (expression? (list-ref x 1))
       (expression? (list-ref x 2))))

(define (expr-equal-lhs x)
  (list-ref x 1))

(define (expr-equal-rhs x)
  (list-ref x 2))

(define (expression->rules vars preconds expr)
  (if (if-form? expr)
      (append (expression->rules vars
                                 (cons (prop-not
                                        (prop-not
                                         (if-form-test expr)))
                                       preconds)
                                 (if-form-then expr))
              (expression->rules vars
                                 (cons (prop-not (if-form-test expr))
                                       preconds)
                                 (if-form-else expr)))
      (if (expr-equal? expr)
          (list (rule vars
                      preconds
                      (expr-equal-lhs expr)
                      (expr-equal-rhs expr))
                (rule vars
                      preconds
                      (expr-equal-rhs expr)
                      (expr-equal-lhs expr)))
          '())))

(define (theorem*->rules def)
  (expression->rules (theorem*-vars def)
                     '()
                     (theorem*-expression def)))

(define current-system (make-parameter (make-system '() '() '())))

(define (add-definition x)
  (let ((sys (current-system)))
    (current-system
     (cond ((lookup (definition-name x) sys)
            => (lambda (d)
                 (if (equal? x d)
                     sys
                     (error "(vikalpa) add-definition: duplicated"
                            (definition-name d)))))
           (else (make-system (cons x (system-definitions sys))
                              (system-proofs sys)
                              (system-totality-claim-list sys)))))
    x))

(define (add-proof x)
  (let ((sys (current-system)))
    (current-system
     (cond ((find-proof (proof-name x) sys)
            => (lambda (prf)
                 (if (equal? x prf)
                     sys
                     (error "add-proof: duplicated"))))
           (else (make-system (system-definitions sys)
                              (cons x (system-proofs sys))
                              (system-totality-claim-list sys)))))
    x))

(define reserved-symbols '(quote let if error))
(define (reserved? x)
  (member x reserved-symbols))

(define-syntax define-axiom
  (syntax-rules ()
    ((_ name (var ...) expr)
     (let ((t (axiom 'name '(var ...)
                     (convert-to-expression 'expr))))
       (add-definition t)
       (validate-definition t)
       t))))

(define-syntax define-theorem
  (syntax-rules ()
    ((_ name (var ...) expr)
     (let ((t (theorem 'name '(var ...)
                       (convert-to-expression 'expr))))
       (add-definition t)
       (validate-definition t)
       t))))

(define-syntax define-function
  (syntax-rules ()
    ((_ name (var ...) expr)
     (let ((f (function 'name '(var ...)
                        (convert-to-expression 'expr)
                        'expr
                        #f)))
       (add-definition f)
       (validate-definition f)
       f))))

(define-syntax define-primitive-function
  (syntax-rules ()
    ((_ name (var ...))
     (let ((f (primitive-function 'name '(var ...))))
       (add-definition f)
       f))
    ((_ name (var ...) expr)
     (let ((f (function 'name '(var ...)
                        (convert-to-expression 'expr)
                        'expr
                        '#t)))
       (add-definition f)
       (validate-definition f)
       f))))

(define-syntax define-syntax-rules
  (syntax-rules ()
    ((_ name (l ...) ((lhs1 . lhs2) rhs) ...)
     (let ((m (macro 'name
                (list (mrule '(lhs1 . lhs2) 'rhs)
                      ...)
                '(l ...))))
       (add-definition m)
       m))))

(define (find-totality-claim name sys)
  (assoc name (system-totality-claim-list sys)))

(define (add-totality-claim tc)
  (let ((sys (current-system)))
    (cond ((find-totality-claim (totality-claim-id tc) sys)
           => (lambda (tc2)
                (unless (equal? tc tc2)
                  (error "(vikalpa) define-totality-claim: duplicated"
                         tc)))))
    (unless (and (symbol? (totality-claim-id tc))
                 (cond ((lookup (totality-claim-natural tc) sys)
                        => function*?)
                       (else #f))
                 (cond ((lookup (totality-claim-less-than tc) sys)
                        => function*?)
                       (else #f)))
      (error "(vikalpa) define-totality-claim: invalid totality-claim"
             tc))
    (current-system
     (make-system (system-definitions sys)
                  (system-proofs sys)
                  (cons tc (system-totality-claim-list sys))))))

(define-syntax-rule (define-totality-claim name nat? <)
  (add-totality-claim (totality-claim 'name 'nat? '<)))

(define* (core-system #:optional (parent (make-system '() '() '())))
  (parameterize ((current-system parent))
    (define-primitive-function not (x))
    (define-primitive-function equal? (x y))
    (define-primitive-function cons (x y))
    (define-primitive-function car (x))
    (define-primitive-function cdr (x))
    (define-primitive-function succ (x))
    (define-primitive-function pred (x))
    (current-system)))

(define-syntax define-system
  (syntax-rules ()
    ((_ name (systems ...) expr ...)
     (define* (name #:optional (parent (make-system '() '() '())))
       (parameterize ((current-system
                       ((compose systems ... core-system) parent)))
         expr
         ...
         (unless (system? (current-system))
           (error "define-system: invalid system"))
         (current-system))))))

(define (measure? x)
  (and (pair? x)
       (variable? (car x))
       (list? (cdr x))
       (<= 1 (length (cdr x)))))

(define (measure-function-name m)
  (car m))

(define (measure-function-vars m)
  (cdr m))

(define (function-app-form f)
  (cons (function-name f) (function-vars f)))

(define (single? x)
  (and (pair? x)
       (null? (cdr x))))

(define (if/if x y z)
  (cond
   ((equal? y z) y)
   ((equal? x ''#t) y)
   ((equal? x ''#f) z)
   (else `(if ,x ,y ,z))))

(define (and/if . args)
  (cond
   ((null? args) ''#t)
   ((equal? ''#t (car args)) (apply and/if (cdr args)))
   (else
    (let ((rest (apply and/if (cdr args))))
      (if (equal? ''#t rest)
          (car args)
          (if/if (car args)
                 rest
                 ''#f))))))

(define (implies/if x y)
  (cond
   ((equal? ''#f x) ''#t)
   ((equal? ''#t y) ''#t)
   (else
    (if/if x y ''#t))))

(define (make-totality-claim tc m-expr f)
  (let* ((name (function-name f)))
    (define (convert app-form)
      (cond
       ((apply-rule '()
                    (rule (function-vars f)
                          '()
                          (function-app-form f)
                          m-expr)
                    app-form
                    '())
        => identity)
       (else (error "make-totality-claim: convert error"
                    (function-name f)
                    m-expr
                    app-form))))
    (if/if `(,(totality-claim-natural tc) ,m-expr)
           (let loop ((expr (function-expression f)))
             (cond
              ((expr-quoted? expr) ''#t)
              ((variable? expr) ''#t)
              ((if-form? expr)
               (let ((test/result (loop (if-form-test expr)))
                     (then/result (loop (if-form-then expr)))
                     (else/result (loop (if-form-else expr))))
                 (and/if test/result
                         (if/if (if-form-test expr)
                                then/result
                                else/result))))
              ((app-form? expr)
               (let ((rest
                      (let f ((args (app-form-args expr)))
                        (cond ((null? args) ''#t)
                              ((single? args) (loop (car args)))
                              (else (and/if (loop (car args))
                                            (f (cdr args))))))))
                 (if (eq? name (app-form-name expr))
                     (and/if `(,(totality-claim-less-than tc)
                               ,(convert expr)
                               ,m-expr)
                             rest)
                     rest)))
              (else (error "(vikalpa) make-totality-claim: error"
                           (function-name f)
                           m-expr))))
           ''#t)))

(define/guard (make-induction-claim (f function*?)
                                    (vars (list-of variable?))
                                    (t theorem?))
  (define (find-app-forms expr)
    (cond
     ((app-form? expr)
      (let ((rest (append-map find-app-forms (cdr expr))))
        (if (eq? (function-name f) (app-form-name expr))
            (cons expr rest)
            rest)))
     ((if-form? expr)
      (error "make-induction-claim(find-app-forms): not supported"
             expr))
     (else '())))
  (let ((c (theorem*-expression t)))
    (define (prop app-form)
      (cond
       ((apply-rule '()
                    (rule vars
                          '()
                          (cons (function-name f) vars)
                          c)
                    app-form
                    '())
        => identity)
       (else
        (error "make-induction-claim: fail" app-form))))
    (cond
     ((apply-function f vars)
      => (lambda (expr)
           (let build ((expr expr))
             (cond
              ((if-form? expr)
               (let ((app-forms (find-app-forms (if-form-test expr))))
                 (implies/if (if (null? app-forms)
                                 ''#t
                                 (fold implies/if c (map prop app-forms)))
                             (if/if (if-form-test expr)
                                    (build (if-form-then expr))
                                    (build (if-form-else expr))))))
              (else
               (let ((app-forms (find-app-forms expr)))
                 (fold implies/if c (map prop app-forms))))))))
     (else (error "make-induction-claim: invalid"
                  f vars t)))))

(define (proof? x)
  (and (list? x)
       (= 4 (length x))
       (symbol? (proof-name x))
       (eq? 'proof (list-ref x 1))
       (seed? (proof-seed x))
       (sequence? (proof-sequence x))))

(define (proof name seed sequence)
  (list name 'proof seed sequence))

(define (proof-name x)
  (list-ref x 0))

(define (proof-seed x)
  (list-ref x 2))

(define (proof-sequence x)
  (list-ref x 3))

(define seed? (const #t))

(define-syntax define-proof
  (syntax-rules ()
    ((_ name
        (seed ...)
        (((n ...) cmd ...) ...))
     (add-proof (proof 'name
                       '(seed ...)
                       '(((n ...) cmd ...) ...))))))

(define (function*? x)
  (or (function? x)
      (primitive-function? x)))

(define (validate-definition d)
  (let* ((expr (definition-expression d))
         (vars (definition-vars d))
         (name (definition-name d))
         (expr-fnames (expression-functions expr))
         (expr-vars (expression-vars expr)))
    (when (reserved? name)
      (error (format #f "(vikalpa) ~a: reserved name" name)))
    (for-each (lambda (x)
                (unless (cond
                         ((lookup x (current-system)) => function*?)
                         (else #f))
                  (error (format #f "(vikalpa) ~a: undefined function" name)
                         x)))
              expr-fnames)
    (for-each (lambda (x)
                (unless (member x vars)
                  (error (format #f "(vikalpa) ~a: undefined variable" name)
                         x))
                (when (member x (if (function? d)
                                    (cons name expr-fnames)
                                    expr-fnames))
                  (error (format #f "(vikalpa) ~a: invalid variable name" name)
                         x)))
              expr-vars)))

(define (trivial-total? f)
  (not (member (function-name f)
               (expression-functions (function-expression f)))))

(define (prove sys def pf)
  (cond
   ((theorem? def)
    (prove/theorem sys def pf))
   ((function? def)
    (prove/function sys def pf))
   (else (error "prove" def pf))))

(define (prove/theorem sys t pf)
  (match (proof-seed pf)
    ((f . vars)
     (cond
      ((lookup f sys)
       => (lambda (seed)
            (rewrite sys
                     (make-induction-claim seed
                                           vars
                                           t)
                     (proof-sequence pf))))
      (else (error "(vikalpa) define-proof: induction function is not found."
                   (proof-name pf)
                   (cons f vars)))))
    (()
     (rewrite sys
              (theorem*-expression t)
              (proof-sequence pf)))
    (else
     (error "prove/theorem: fail"))))

(define (prove/function sys f pf)
  (match (proof-seed pf)
    ((id m-expr)
     (cond
      ((find-totality-claim id sys)
       => (lambda (tc)
            (rewrite sys
                     (make-totality-claim tc m-expr f)
                     (proof-sequence pf))))
      (else
       (error "(vikalpa) define-proof: totality-claim is not found:"
              (proof-name pf)
              (proof-seed pf)))))
    (else
     (error "define-proof: fail"
            (proof-name pf) (proof-seed pf)))))

(define (system->scheme sys)
  `(begin
     ,@(map (lambda (f)
              `(define (,(function-name f) ,@(function-vars f))
                 ,(function-code f)))
            (reverse (filter (lambda (x)
                               (and (function? x)
                                    (not (function-primitive? x))))
                             (system-definitions sys))))))

(define/guard (check (sys system?))
  (let loop ((sys sys)
             (fails '()))
    (let ((defs (system-definitions sys)))
      (define* (next #:optional fail)
        (loop (make-system (cdr defs)
                           (system-proofs sys)
                           (system-totality-claim-list sys))
              (if fail
                  (cons fail fails)
                  fails)))
      (cond
       ((null? defs) fails)
       ((or (theorem? (car defs))
            (function? (car defs)))
       (cond
         ((and (function? (car defs))
               (trivial-total? (car defs)))
          (next))
         (else
          (cond
           ((find-proof (definition-name (car defs)) sys)
            => (lambda (pf)
                 (let ((result (prove sys (car defs) pf)))
                   (cond
                    ((equal? result ''#t)
                     (next))
                    (else
                     (next (list (definition-name (car defs))
                                 result)))))))
           (else
            (next (list (definition-name (car defs)))))))))
       (else
        (next))))))

(define (pp x)
  (pretty-print x
                #:width 79
                #:max-expr-width 50))

(define/guard (show (sys system?) (name symbol?))
  (cond
   ((lookup name sys)
    => (lambda (def)
         (cond
          ((function? def)
           `(define-function ,(function-name def) ,(function-vars def)
              ,(function-expression def)))
          ((theorem? def)
           `(define-theorem ,(theorem*-name def) ,(theorem*-vars def)
              ,(theorem*-expression def)))
          ((axiom? def)
           `(define-axiom ,(theorem*-name def) ,(theorem*-vars def)
              ,(theorem*-expression def)))
          ((primitive-function? def)
           `(define-primitive-function
              ,(primitive-function-name def)
              ,(primitive-function-vars def)))
          ((macro? def)
           `(define-syntax-rules ,(macro-name def)))
          (else
           `(error 'fatal-error ,name)))))
   (else
    `(error 'not-found ,name))))

(define/guard (load-system (sys system?))
  (primitive-eval (system->scheme sys)))

(define/guard (system-primitives (sys system?))
  (append reserved-symbols
          (map primitive-function-name
               (filter primitive-function?
                       (system-definitions sys)))))

(define/guard (system-functions (sys system?))
  (map function-name
       (filter function?
               (system-definitions sys))))

(define/guard (system-theorems (sys system?))
  (map theorem-name
       (filter theorem?
               (system-definitions sys))))

(define/guard (system-axioms (sys system?))
  (map theorem*-name
       (filter axiom?
               (system-definitions sys))))

(define/guard (system-macros (sys system?))
  (map macro-name
       (filter macro?
               (system-definitions sys))))

(define/guard (system-totality-claims (sys system?))
  (system-totality-claim-list sys))