;;; Vikalpa --- Proof Assistant
;;; Copyright © 2020 Masaya Tojo <masaya@tojo.tokyo>
;;;
;;; This file is part of Vikalpa.
;;;
;;; Vikalpa is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or
;;; (at your option) any later version.
;;;
;;; Vikalpa is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
;;; General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with Vikalpa.  If not, see <http://www.gnu.org/licenses/>.

(define-module (vikalpa)
  #:export (rewrite
            describe
            system-check
            system-apropos
            system-code
            system-load
            set-measure-predicate
            set-measure-less-than
            define-system
            define-proof
            define-core-function
            define-function
            define-theorem)
  #:use-module (ice-9 match)
  #:use-module (ice-9 format)
  #:use-module (ice-9 control)
  #:use-module (ice-9 exceptions)
  #:use-module (ice-9 regex)
  #:use-module ((srfi srfi-1)
                #:select (every any member lset-union fold append-map
                                find))
  #:use-module (srfi srfi-8)
  #:use-module (srfi srfi-11)
  #:use-module (srfi srfi-26)
  #:use-module (ice-9 pretty-print)
  #:use-module (oop goops))

(define-class <system> ()
  (definitions
    #:getter get-definitions
    #:init-keyword #:definitions
    #:init-value '())
  (measure-predicate #:getter get-measure-predicate
                     #:init-value #f)
  (measure-less-than #:getter get-measure-less-than
                     #:init-value #f))

(define-class <definition> ()
  (name #:getter get-name
        #:init-keyword #:name)
  (variables #:getter get-variables
             #:init-keyword #:variables
             #:init-value '()))

(define-class <provable> ())

(define-class <proved> (<provable>)
  (claim #:getter get-claim #:init-keyword #:claim)
  (proof #:getter get-proof #:init-keyword #:proof))

(define-class <theorem*> (<definition>)
  (expression #:getter get-expression #:init-keyword #:expression))

(define-class <conjecture> (<theorem*> <provable>))
(define-class <theorem> (<theorem*> <proved>))
(define-class <axiom> (<theorem*>))

(define-class <function*> (<definition>)
  (conditions #:getter get-conditions #:init-keyword #:conditions))
(define-class <core-function> (<function*>)
  (procedure #:getter get-procedure #:init-keyword #:procedure))
(define-class <expandable-function> (<function*>)
  (expression #:getter get-expression #:init-keyword #:expression)
  (code #:getter get-code #:init-keyword #:code))
(define-class <function> (<expandable-function> <provable>))
(define-class <total-function> (<expandable-function> <proved>))
(define-class <trivial-total-function> (<expandable-function>))

(define-generic macro-mrules)
(define-generic macro-literals)
(define-class <macro> (<definition>)
  (mrules #:getter macro-mrules #:init-keyword #:mrules)
  (literals #:getter macro-literals #:init-keyword #:literals))

(define (write-definition sym d port)
  (format port "#<~a: ~s>"
          sym (cons (get-name d) (get-variables d))))

(define-method (write (s <system>) port)
  (format port "#<system: function: ~a theorem: ~a macro: ~a>"
          (length (filter (cut is-a? <> <function*>)
                          (get-definitions s)))
          (length (filter (cut is-a? <> <theorem*>)
                          (get-definitions s)))
          (length (filter (cut is-a? <> <macro>)
                          (get-definitions s)))))

(define-method (write (d <macro>) port)
  (write-definition 'macro d port))
(define-method (write (d <conjecture>) port)
  (write-definition 'conjecture d port))
(define-method (write (d <theorem>) port)
  (write-definition 'theorem d port))
(define-method (write (d <axiom>) port)
  (write-definition 'axiom d port))
(define-method (write (d <axiom>) port)
  (write-definition 'axiom d port))
(define-method (write (d <function>) port)
  (write-definition 'function d port))
(define-method (write (d <core-function>) port)
  (write-definition 'core-function d port))
(define-method (write (d <trivial-total-function>) port)
  (write-definition 'trivial-total-function d port))
(define-method (write (d <total-function>) port)
  (write-definition 'total-function d port))

(define-generic lookup)
(define-method (lookup (name <symbol>) (s <system>))
  (find (lambda (x)
          (eq? name (get-name x)))
        (get-definitions s)))

(define-generic update-measure-predicate)
(define-method (update-measure-predicate (s <symbol>) (sys <system>))
  (let ((new (shallow-clone sys)))
    (slot-set! new 'measure-predicate s)
    new))

(define-generic update-measure-less-than)
(define-method (update-measure-less-than (s <symbol>) (sys <system>))
  (let ((new (shallow-clone sys)))
    (slot-set! new 'measure-less-than s)
    new))

(define-generic update-definition)
(define-method (update-definition (d <definition>) (sys <system>))
  (define (update d defs)
    (if (null? defs)
        (raise-exception
         (make-exception
          (make-exception-with-origin 'update-definition)
          (make-exception-with-message "not found")
          (make-exception-with-irritants (list d defs))))
        (if (equal? (get-name d) (get-name (car defs)))
            (cons d (cdr defs))
            (cons (car defs) (update d (cdr defs))))))
  (let ((new (shallow-clone sys)))
    (slot-set! new 'definitions
               (update d (get-definitions sys)))
    new))
(define-generic remove-first-definition)
(define-method (remove-first-definition (sys <system>))
  (let ((new (shallow-clone sys)))
    (slot-set! new 'definitions
               (cdr (get-definitions sys)))
    new))
(define-generic first-definition)
(define-method (first-definition (sys <system>))
  (car (get-definitions sys)))

(define-generic system-empty?)
(define-method (system-empty? (sys <system>))
  (null? (get-definitions sys)))

(define-generic add-definition)
(define-method (add-definition (d <definition>) (s <system>))
  (if (lookup (get-name d) s)
      (raise-exception
       (make-exception
        (make-exception-with-origin 'add-definition)
        (make-exception-with-message "duplicated definition")
        (make-exception-with-irritants (get-name d))))
      (let ((new (shallow-clone s)))
        (slot-set! new 'definitions
                   (cons d (get-definitions s)))
        new)))

(define-generic validate)
(define-method (validate (d <definition>))
  (let* ((vars (get-variables d))
         (name (get-name d)))
    (validate-vars (symbol->string name) vars)))

(define-method (validate (d <expandable-function>))
  (let* ((vars (get-variables d))
         (name (get-name d))
         (expr (get-expression d)))
    (validate-expression (current-system) name vars expr)
    (next-method)))

(define-method (validate (d <theorem*>))
  (let* ((vars (get-variables d))
         (name (get-name d))
         (expr (get-expression d)))
    (validate-expression (current-system) name vars expr)
    (next-method)))

(define (debug f . args)
  (if #f
      (apply format #t f args)
      #t))

(define-syntax-rule (define/guard (name (var p?) ...) b b* ...)
  (define (name var ...)
    (unless (p? var)
      (error (format #f
                     "~a:~%  expected:  ~a~%  given: "
                     'name
                     'p?)
             var))
    ...
    b b* ...))

(define-syntax define-type
  (syntax-rules ()
    ((_ name
        constractor
        (m p?)
        (n t? getter-var getter) ...)
     (begin
       (define (constractor getter-var ...)
         (let ((data (make-list (+ 1 (length (list t? ...))))))
           (list-set! data m 'name)
           (list-set! data n getter-var)
           ...
           data))
       (define (p? x)
         (and (list? x)
              (= (+ 1 (length (list t? ...))) (length x))
              (eq? 'name (list-ref x m))
              (t? (list-ref x n)) ...))
       (define (getter x)
         (list-ref x n))
       ...))))

;; (natural? x) -> boolean?
(define (natural? x)
  (and (exact-integer? x)
       (not (negative? x))))

(define (option p?)
  (lambda (x)
    (or (p? x) (not x))))

(define (list-of p?)
  (lambda (x)
    (and (list? x)
         (every p? x))))

;; (expression? x) -> boolean?
(define (expression? expr)
  (cond ((expr-quoted? expr)
         (or (natural? (expr-unquote expr))
             (boolean? (expr-unquote expr))
             (symbol? (expr-unquote expr))
             (null? (expr-unquote expr))))
        ((if-form? expr)
         (and (expression? (if-form-test expr))
              (expression? (if-form-then expr))
              (expression? (if-form-else expr))))
        ((app-form? expr)
         (and (symbol? (car expr))
              (list? (cdr expr))
              (every expression? (cdr expr))))
        ((variable? expr) #t)
        (else #f)))

(define (app-form? expr)
  (and (pair? expr)
       (not (eq? (car expr) 'quote))
       (not (eq? (car expr) 'if))))

(define (app-form name args)
  (cons name args))

(define (app-form-name expr)
  (car expr))

(define (app-form-args expr)
  (cdr expr))

(define (if-form test then else)
  (list 'if test then else))

(define (if-form? x)
  (and (pair? x)
       (eq? (car x) 'if)))

(define (if-form-test expr)
  (list-ref expr 1))

(define (if-form-then expr)
  (list-ref expr 2))

(define (if-form-else expr)
  (list-ref expr 3))

(define (expression-app-forms expr)
  (cond
   ((if-form? expr)
    (append-map expression-app-forms
                (list (if-form-test expr)
                      (if-form-then expr)
                      (if-form-else expr))))
   ((app-form? expr)
    (cons expr
          (append-map expression-app-forms
                      (app-form-args expr))))
   (else '())))

(define (expression-functions expr)
  (cond
   ((if-form? expr)
    (apply lset-union
           eq?
           (map expression-functions
                (list (if-form-test expr)
                      (if-form-then expr)
                      (if-form-else expr)))))
   ((app-form? expr)
    (cons (app-form-name expr)
          (apply lset-union
                 eq?
                 (map expression-functions (app-form-args expr)))))
   (else '())))

(define (expression-vars expr)
  (cond
   ((expr-quoted? expr) '())
   ((if-form? expr)
    (lset-union eq?
                (expression-vars (if-form-test expr))
                (expression-vars (if-form-then expr))
                (expression-vars (if-form-else expr))))
   ((app-form? expr)
    (apply lset-union
           eq?
           (map expression-vars (app-form-args expr))))
   ((variable? expr) (list expr))
   (else '())))

;; (expr-quoted? x) -> boolean?
(define (expr-quoted? expr)
  (and (pair? expr)
       (eq? 'quote (car expr))
       (pair? (cdr expr))
       ((const #t) (car (cdr expr)))
       (null? (cdr (cdr expr)))))

(define (expr-unquote expr)
  (car (cdr expr)))

;; (expr-quoted? x) -> boolean?
(define (expr-quote expr)
  (list 'quote expr))

;; (variable? x) -> boolean?
(define (variable? x)
  (symbol? x))

;; (variable=? variable? variable?) -> boolean?
(define (variable=? v1 v2)
  (eq? v1 v2))

(define-type rule
  rule
  (0 rule?)
  (1 (lambda (vars)
       (and (list? vars)
            (every variable? vars)))
     vars
     rule-vars)
  (2 (lambda (ps)
       (and (list? ps)
            (every expression? ps)))
     ps
     rule-preconds)
  (3 expression?
     lhs
     rule-lhs)
  (4 expression?
     rhs
     rule-rhs))

(define (binding? x)
  (and (pair? x)
       (symbol? (car x))
       (expression? (cdr x))))

(define (env? x)
  ((list-of binding?) x))

(define/guard (substitute (env env?) (expr (const #t)))
  (debug "substitute: ~s ~s~%" env expr)
  (cond ((expr-quoted? expr) expr)
        ((pair? expr)
         (cons (substitute env (car expr))
               (substitute env (cdr expr))))
        ((assoc expr env) => cdr)
        (else expr)))

(define (match-rule preconds rl expr env)
  (define (fail)
    (shift k #f))
  (define (var? v)
    (and (member v (rule-vars rl))
         #t))
  (define (add-env var expr env)
    (cond
     ((assoc var env)
      => (match-lambda
           ((env-var . env-expr)
            (if (equal? env-expr expr)
                env
                (fail)))))
     (else
      (cons (cons var expr)
            env))))
  (define (mat-fold lhss exprs env)
    (cond ((and (pair? lhss) (pair? exprs))
           (mat-fold (cdr lhss)
                     (cdr exprs)
                     (mat (car lhss)
                          (car exprs)
                          env)))
          ((and (null? lhss) (null? exprs)) env)
          (else (fail))))
  (define (mat-begin lhs expr env)
    (reset (mat lhs expr env)))
  (define (mat lhs expr env)
    (debug "lhs ~a, expr ~a, env ~a~%" lhs expr env)
    (cond ((expr-quoted? lhs)
           (if (expr-quoted? expr)
               (if (equal? lhs expr)
                   env
                   (fail))
               (fail)))
          ((and (if-form? lhs)
                (if-form? expr))
           (mat-fold (list (if-form-test lhs)
                           (if-form-then lhs)
                           (if-form-else lhs))
                     (list (if-form-test expr)
                           (if-form-then expr)
                           (if-form-else expr))
                     env))
          ((app-form? lhs)
           (if (and (app-form? expr)
                    (symbol? (app-form-name lhs))
                    (eqv? (app-form-name lhs) (app-form-name expr)))
               (mat-fold (app-form-args lhs) (app-form-args expr) env)
               (fail)))
          ((var? lhs) (add-env lhs expr env))
          (else (fail))))
  (define (mat-preconds rlps k+env)
    (if (null? rlps)
        k+env
        (mat-preconds
         (cdr rlps)
         (let search ((ps preconds))
           (if (null? ps)
               (shift k ((car k+env) #f))
               (let ((env (mat-begin (car rlps) (car ps) (cdr k+env))))
                 (cond
                  ((mat-begin (car rlps) (car ps) (cdr k+env))
                   => (lambda (env)
                        (shift k0
                               (reset
                                (or (shift k (k0 (cons k env)))
                                    (k0 (search (cdr ps))))))))
                  (else (search (cdr ps))))))))))
  (define (valid? env expr)
    (cond ((expr-quoted? expr) #t)
          ((pair? expr)
           (and (valid? env (car expr))
                (valid? env (cdr expr))))
          ((var? expr)
           (cond ((assoc expr env) => (const #t))
                 (else #f)))
          (else #t)))
  (debug "rule: ~a~%" rl)
  (debug "preconds: ~a~%" preconds)
  (debug "expr: ~a~%" expr)
  (reset
   (shift k0
          (match (mat-preconds (rule-preconds rl) (cons k0 env))
            ((k . env)
             (cond
              ((mat-begin (rule-lhs rl) expr env)
               => (lambda (env)
                    (if (valid? env (rule-rhs rl))
                        env
                        (k #f))))
              (else (k #f))))
            (else #f)))))

;; (apply-rule preconds rule? expression?) -> (or (cons rhs env?) #f)
(define (apply-rule preconds rl expr env)
  (cond
   ((match-rule preconds rl expr env)
    => (cut substitute <> (rule-rhs rl)))
   (else #f)))

(define-type code
  code
  (0 code?)
  (1 (const #t)
     expr
     code-expr))

(define-generic mrule-lhs)
(define-generic mrule-rhs)
(define-class <mrule> ()
  (lhs #:getter mrule-lhs #:init-keyword #:lhs)
  (rhs #:getter mrule-rhs #:init-keyword #:rhs))

(define (mrule lhs rhs)
  (make <mrule> #:lhs lhs #:rhs rhs))

(define (mrule-vars mrl)
  (define (all-vars x)
    (cond ((expr-quoted? x) '())
          ((pair? x)
           (append (all-vars (car x))
                   (all-vars (cdr x))))
          ((variable? x) (list x))
          (else '())))
  (all-vars (mrule-lhs mrl)))

(define (macro name mrules literals)
  (make <macro>
    #:name name
    #:variables '()
    #:mrules mrules
    #:literals literals))

(define (apply-mrule rl ls expr)
  (define (literal? x)
    (member x ls))
  (define (var? v)
    (and (member v (mrule-vars rl))
         #t))
  (call/cc
   (lambda (k)
     (define (mat-map lhs-tree expr-tree env)
       (cond ((and (pair? lhs-tree)
                   (pair? expr-tree))
              (mat-map (car lhs-tree)
                       (car expr-tree)
                       (mat-map (cdr lhs-tree)
                                (cdr expr-tree)
                                env)))
             (else (mat lhs-tree expr-tree env))))
     (define (mat lhs expr env)
       (cond ((expr-quoted? lhs)
              (if (expr-quoted? expr)
                  (if (equal? lhs expr)
                      env
                      (k #f))
                  (k #f)))
             ((and (pair? lhs) (pair? expr))
              (mat-map lhs expr env))
             ((literal? lhs)
              (if (eq? lhs expr)
                  env
                  (k #f)))
             ((var? lhs)
              (cond
               ((assoc lhs env)
                => (match-lambda
                     ((env-var . env-expr)
                      (if (equal? env-expr expr)
                          env
                          (k #f)))))
               (else
                (cons (cons lhs expr)
                      env))))
             ((eqv? lhs expr) env)
             (else (k #f))))
     (define (mrule-substitute env expr)
       (cond ((expr-quoted? expr) expr)
             ((pair? expr)
              (cons (mrule-substitute env (car expr))
                    (mrule-substitute env (cdr expr))))
             ((literal? expr) expr)
             ((and (variable? expr) (assoc expr env)) => cdr)
             (else expr)))
     (mrule-substitute (mat (mrule-lhs rl)
                            expr
                            '())
                       (mrule-rhs rl)))))

(define (apply-macro m expr)
  (cond ((and (pair? expr)
              (eq? (get-name m) (car expr)))
         (let loop ((rs (macro-mrules m)))
           (cond ((null? rs)
                  (error "(vikalpa) macro fail" m expr))
                 ((apply-mrule (car rs) (macro-literals m) expr) => identity)
                 (else (loop (cdr rs))))))
        (else #f)))

(define (expand ms expr)
  (let loop ((ms ms)
             (expr expr))
    (cond
     ((null? ms) expr)
     (else
      (expand (cdr ms)
              (cond
               ((apply-macro (car ms) expr) => identity)
               (else expr)))))))

(define (expand* ms expr)
  (let loop ((ms ms)
             (expr expr))
    (let ((new-expr (expand ms expr)))
      (if (equal? expr new-expr)
          (if (pair? new-expr)
              (cons (expand* ms (car new-expr))
                    (expand* ms (cdr new-expr)))
              new-expr)
          (expand* ms new-expr)))))

(define (quote-all x)
  (cond
   ((null? x) x)
   ((expr-quoted? x) x)
   ((pair? x)
    (cons (quote-all (car x))
          (quote-all (cdr x))))
   ((symbol? x) x)
   (else `',x)))

(define (let? x)
  (and (list? x)
       (= 3 (length x))
       (eq? 'let (list-ref x 0))
       ((list-of (lambda (x)
                   (and (list? x)
                        (= 2 (length x))
                        (symbol? (car x)))))
        (list-ref x 1))))

(define (expand-let x)
  (define (let-substitute env expr)
    (cond ((expr-quoted? expr) expr)
          ((let? expr)
           (let-substitute
            (append (map (lambda (binding)
                           (cons (car binding)
                                 (let-substitute env
                                                 (cadr binding))))
                         (list-ref expr 1))
                    env)
            (list-ref expr 2)))
          ((pair? expr)
           (cons (let-substitute env (car expr))
                 (let-substitute env (cdr expr))))
          ((assoc expr env) => cdr)
          (else expr)))
  (cond
   ((expr-quoted? x) x)
   ((let? x)
    (expand-let
     (let-substitute (map (lambda (binding) (cons (car binding)
                                                  (cadr binding)))
                          (list-ref x 1))
                     (list-ref x 2))))
   ((pair? x)
    (cons (expand-let (car x))
          (expand-let (cdr x))))
   (else x)))

(define (convert-to-expression x)
  (quote-all
   (expand* (filter (cut is-a? <> <macro>)
                    (get-definitions (current-system)))
            (expand-let x))))

(define (vars? x)
  (and (list? x)
       (every variable? x)))

(define (theorem-rules x)
  (expression->rules (get-variables x)
                     '()
                     (get-expression x)))

(define (rewrite/eval expr sys)
  (let eval ((expr expr))
    (cond
     ((expr-quoted? expr) expr)
     ((app-form? expr)
      (let ((args (map eval (app-form-args expr)))
            (name (app-form-name expr)))
        (or (find error? args)
            (eval (rewrite1 sys
                            `(,name ,@args)
                            (lambda args
                              (cons* 'error 'rewrite name args))
                            (rewriter '() `(,name)))))))
     ((if-form? expr)
      (let ((test (eval (if-form-test expr))))
        (if (error? test)
            test
            (if (expr-unquote test)
                (eval (if-form-then expr))
                (eval (if-form-else expr))))))
     (else
      `(error eval invalid-expression ,expr)))))

;; (rewriter path? command?) -> rewriter?
(define (rewriter p c)
  (cons p c))

(define (rewriter-path r)
  (car r))

(define (rewriter-command r)
  (cdr r))

(define (rewriter? x)
  (and (pair? x)
       (path? (car x))
       (command? (cdr x))))

;; (sequence? x) -> boolean?
(define (sequence? x)
  (and (list? x)
       (every rewriter? x)))

;; (path? x) -> boolean?
;; path is list
(define (path? x)
  (and (list? x)
       (every natural? x)))

;; (command-name? x) -> booelan?
(define (command? x)
  (and (pair? x)
       (command-name? (car x))
       ((list-of command-option?) (cdr x))))

;; (command-name? x) -> booelan?
(define (command-name? x)
  (or (symbol? x)
      ((list-of symbol?) x)))

;; (command-option? x) -> boolean?
(define (command-option? x)
  (and (pair? x)
       (case (car x)
         ((set) (and (list? x)
                     (= 3 (length x))
                     (variable? (list-ref x 1))
                     (expression? (list-ref x 2))))
         (else #f))))

(define (command-name x)
  (car x))

(define (command-options x)
  (cdr x))

(define/guard (system-eval (expr (const #t)) (sys (cut is-a? <> <system>)))
  (rewrite/eval (parameterize ((current-system sys))
                  (convert-to-expression expr))
                sys))

;; (extract path? expression? preconds? procedure?) -> (values expression? procedure?)
(define (extract path expr fail)
  (if (null? path)
      (values expr '() identity)
      (let ((i (car path)))
        (cond
         ((if-form? expr)
          (let ((precond (if-form-test expr)))
            (receive (extracted-expr extracted-preconds builder)
                (extract (cdr path) (list-ref expr i) fail)
              (values extracted-expr
                      (case i
                        ((1) '())
                        ((2) (cons (prop-not (prop-not precond))
                                   extracted-preconds))
                        ((3) (cons (prop-not precond) extracted-preconds))
                        (else (fail 'if-invaild-path path)))
                      (lambda (x)
                        (append (list-head expr i)
                                (list (builder x))
                                (list-tail expr (+ i 1))))))))
         ((< i (length expr))
          (receive (extracted-expr preconds builder)
              (extract (cdr path) (list-ref expr i) fail)
            (values extracted-expr
                    preconds
                    (lambda (x)
                      (append (list-head expr i)
                              (list (builder x))
                              (list-tail expr (+ i 1)))))))
         (else
          (fail 'invalid-path path))))))

(define (function->rules x)
  (list (rule (get-variables x)
              (get-conditions x)
              (defined-function-app-form x)
              (get-expression x))
        (rule (get-variables x)
              (get-conditions x)
              (get-expression x)
              (defined-function-app-form x))))

(define (apply-function f args)
  (apply-rule '()
              (rule (get-variables f)
                    '()
                    (defined-function-app-form f)
                    (get-expression f))
              (app-form (get-name f) args)
              '()))

(define (parse-options/theorem ops fail)
  (if (null? ops)
      (values '())
      (receive (env)
          (parse-options/theorem (cdr ops) fail)
        (case (caar ops)
          ((set) (let ((op (car ops)))
                   (cons (cons (list-ref op 1)
                               (list-ref op 2))
                         env)))
          (else
           (fail 'invalid-option (car ops)))))))

(define (rewrite/theorem cmd b thm preconds expr fail)
  (receive (env)
      (parse-options/theorem (command-options cmd) fail)
    (cond
     ((any (cut apply-rule preconds <> expr env)
           (theorem-rules thm)) => identity)
     (else
      (fail 'apply-theorem cmd expr)))))

(define (rewrite/induction sys fname vars expr fail)
  (cond
   ((lookup fname sys)
    => (cut make-induction-claim <> vars expr))
   (else (fail 'induction 'not-found fname))))

(define (rewrite1 sys expr fail r)
  (let* ((cmd (rewriter-command r))
         (cmd/name (command-name cmd)))
    (debug "~%~%cmd: ~a~%" cmd)
    (receive (extracted-expr preconds builder)
        (extract (rewriter-path r) expr fail)
      (builder
       (cond
        ((equal? '(eval) cmd/name)
         (rewrite/eval extracted-expr sys))
        ((and (symbol? cmd/name)
              (lookup cmd/name sys))
         => (lambda (x)
              (cond
               ((is-a? x <theorem*>)
                (rewrite/theorem cmd sys x preconds extracted-expr fail))
               ((is-a? x <expandable-function>)
                (cond
                 ((any (cut apply-rule '() <> extracted-expr '())
                       (function->rules x))
                  => identity)
                 (else
                  (fail 'apply-function cmd extracted-expr))))
               (else
                (fail 'invalid-command cmd extracted-expr)))))
        (else (fail 'command-not-found cmd extracted-expr)))))))

(define/guard (rewrite (sys (cut is-a? <> <system>)) (expr (const #t)) (seq (const #t)))
  (let ((expr (convert-to-expression expr)))
    (let loop ((expr expr)
               (seq seq))
      (reset
       (if (null? seq)
           expr
           (loop (rewrite1 sys
                           expr
                           (lambda args
                             (shift k (cons 'error args)))
                           (car seq))
                 (cdr seq)))))))

(define (expr-not x)
  (list 'not x))

(define (prop-not x)
  (match x
    (('not ('not expr)) (prop-not expr))
    (('not expr) expr)
    (expr (expr-not expr))))

(define (expr-equal? x)
  (and (list? x)
       (= 3 (length x))
       (eq? 'equal? (list-ref x 0))
       (expression? (list-ref x 1))
       (expression? (list-ref x 2))))

(define (expr-equal-lhs x)
  (list-ref x 1))

(define (expr-equal-rhs x)
  (list-ref x 2))

(define (expression->rules vars preconds expr)
  (if (if-form? expr)
      (append (expression->rules vars
                                 (cons (prop-not
                                        (prop-not
                                         (if-form-test expr)))
                                       preconds)
                                 (if-form-then expr))
              (expression->rules vars
                                 (cons (prop-not (if-form-test expr))
                                       preconds)
                                 (if-form-else expr))
              (expression->rules vars
                                 preconds
                                 (if-form-test expr)))
      (if (expr-equal? expr)
          (list (rule vars
                      preconds
                      (expr-equal-lhs expr)
                      (expr-equal-rhs expr))
                (rule vars
                      preconds
                      (expr-equal-rhs expr)
                      (expr-equal-lhs expr)))
          '())))

(define (theorem->rules def)
  (expression->rules (get-variables def)
                     '()
                     (get-expression def)))

(define current-system (make-parameter (make <system>)))
(define reserved-symbols '(quote let if error))
(define (reserved? x)
  (member x reserved-symbols))

(define-syntax define-axiom
  (syntax-rules ()
    ((_ name (var ...) expr)
     (let ((t (make <axiom>
                #:name 'name
                #:variables '(var ...)
                #:expression (convert-to-expression 'expr))))
       (current-system (add-definition t (current-system)))
       (validate t)
       t))))

(define-syntax define-theorem
  (syntax-rules ()
    ((_ name (var ...) expr)
     (let ((t (make <conjecture>
                #:name 'name
                #:variables '(var ...)
                #:expression (convert-to-expression 'expr))))
       (current-system (add-definition t (current-system)))
       (validate t)
       t))))

(define-syntax define-core-function
  (syntax-rules ()
    ((_ name (var ...) precond ... proc)
     (let ((f (make <core-function>
                #:name 'name
                #:variables '(var ...)
                #:conditions '(precond ...)
                #:procedure proc)))
       (current-system (add-definition f (current-system)))
       (validate f)
       f))))

(define-syntax define-function
  (syntax-rules ()
    ((_ name (var ...) precond ... expr)
     (let ((f (make <function>
                #:name 'name
                #:variables '(var ...)
                #:conditions '(precond ...)
                #:expression (convert-to-expression 'expr)
                #:code (code 'expr))))
       (current-system (add-definition f (current-system)))
       (validate f)
       f))))

(define-syntax define-function/no-code
  (syntax-rules ()
    ((_ name (var ...) precond ... expr)
     (let ((f (make <function>
                #:name 'name
                #:variables '(var ...)
                #:conditions '(precond ...)
                #:expression (convert-to-expression 'expr)
                #:code (code 'expr))))
       (current-system (add-definition f (current-system)))
       (validate f)
       f))))

(define-syntax define-trivial-total-function
  (syntax-rules ()
    ((_ name (var ...) precond ... expr)
     (let ((f (make <trivial-total-function>
                #:name 'name
                #:variables '(var ...)
                #:conditions '(precond ...)
                #:expression (convert-to-expression 'expr)
                #:code (code 'expr))))
       (current-system (add-definition f (current-system)))
       (validate f)
       f))))

(define-syntax define-syntax-rules
  (syntax-rules ()
    ((_ name (l ...) ((lhs1 . lhs2) rhs) ...)
     (let ((m (macro 'name
                (list (mrule '(lhs1 . lhs2) 'rhs)
                      ...)
                '(l ...))))
       (current-system (add-definition m (current-system)))
       m))))

(define-syntax define-system
  (syntax-rules ()
    ((_ name (systems ...) expr ...)
     (define* (name #:optional (parent (make <system>)))
       (parameterize ((current-system
                       ((compose systems ... identity) parent)))
         expr
         ...
         (current-system))))))

(define (validate-function-name desc name)
  (define (err)
    (raise-exception
     (make-exception
      (make-exception-with-origin 'desc)
      (make-exception-with-message "unbound function")
      (make-exception-with-irritants name))))
  (cond
   ((lookup name (current-system))
    => (lambda (f)
         (if (is-a? f <function*>)
             name
             (err))))
   (else (err))))

(define-syntax set-measure-predicate
  (syntax-rules ()
    ((_ name)
     (begin
       (validate-function-name 'set-measure-predicate 'name)
       (current-system (update-measure-predicate 'name (current-system)))))))

(define-syntax set-measure-less-than
  (syntax-rules ()
    ((_ name)
     (begin
       (validate-function-name 'set-measure-less-than 'name)
       (current-system
        (update-measure-less-than 'name (current-system)))))))

(define (defined-function-app-form f)
  (app-form (get-name f) (get-variables f)))

(define (single? x)
  (and (pair? x)
       (null? (cdr x))))

(define (if/if x y z)
  (cond
   ((equal? y z) y)
   ((equal? x ''#t) y)
   ((equal? x ''#f) z)
   (else `(if ,x ,y ,z))))

(define (and/if . args)
  (cond
   ((null? args) ''#t)
   ((equal? ''#t (car args)) (apply and/if (cdr args)))
   (else
    (let ((rest (apply and/if (cdr args))))
      (if (equal? ''#t rest)
          (car args)
          (if/if (car args)
                 rest
                 ''#f))))))

(define (implies/if x y)
  (cond
   ((equal? ''#f x) ''#t)
   ((equal? ''#t y) ''#t)
   (else
    (if/if x y ''#t))))

(define (make-totality-claim* sys m-expr f)
  (let* ((name (get-name f)))
    (define (convert app-form)
      (cond
       ((apply-rule '()
                    (rule (get-variables f)
                          '()
                          (defined-function-app-form f)
                          m-expr)
                    app-form
                    '())
        => identity)
       (else (error "make-totality-claim: convert error"
                    (get-name f)
                    m-expr
                    app-form))))
    (if/if `(,(get-measure-predicate sys) ,m-expr)
           (let loop ((expr (get-expression f)))
             (cond
              ((expr-quoted? expr) ''#t)
              ((variable? expr) ''#t)
              ((if-form? expr)
               (let ((test/result (loop (if-form-test expr)))
                     (then/result (loop (if-form-then expr)))
                     (else/result (loop (if-form-else expr))))
                 (and/if test/result
                         (if/if (if-form-test expr)
                                then/result
                                else/result))))
              ((app-form? expr)
               (let ((rest
                      (let f ((args (app-form-args expr)))
                        (cond ((null? args) ''#t)
                              ((single? args) (loop (car args)))
                              (else (and/if (loop (car args))
                                            (f (cdr args))))))))
                 (if (eq? name (app-form-name expr))
                     (and/if `(,(get-measure-less-than sys)
                               ,(convert expr)
                               ,m-expr)
                             rest)
                     rest)))
              (else (error "(vikalpa) make-totality-claim: error"
                           (get-name f)
                           m-expr))))
           ''#f)))

(define (make-guard-claim expr sys)
  (define (find-preconds expr)
    (cond
     ((app-form? expr)
      (let ((rest (append-map find-preconds (cdr expr))))
        (append (cond ((lookup (car expr) sys) =>
                       (lambda (f)
                         (let ((preconds (get-conditions f)))
                           (map (lambda (precond)
                                  (substitute (map cons
                                                   (get-variables f)
                                                   (cdr expr))
                                              precond))
                                preconds))))
                      (else (error "make-guard-claim: error")))
                rest)))
     ((if-form? expr)
      (find-preconds (if-form-test expr)))
     (else '())))
  (define (build/find-if expr)
    (cond
     ((if-form? expr)
      (if/if (build/find-if (if-form-test expr))
             (build (if-form-then expr))
             (build (if-form-else expr))))
     ((app-form? expr)
      (apply and/if (map build/find-if (app-form-args expr))))
     (else ''#t)))
  (define (build expr)
    (cond
     ((if-form? expr)
      (apply and/if
             (append (find-preconds (if-form-test expr))
                     (list (if/if (if-form-test expr)
                                  (build (if-form-then expr))
                                  (build (if-form-else expr)))))))
     ((app-form? expr)
      (apply and/if
             (append (find-preconds expr)
                     (list (build/find-if expr)))))
     (else ''#t)))
  (if/if (build expr)
         ''#t
         ''#f))

(define (make-induction-claim f vars c)
  (define (find-app-forms expr)
    (cond
     ((app-form? expr)
      (let ((rest (append-map find-app-forms (cdr expr))))
        (if (eq? (get-name f) (app-form-name expr))
            (cons expr rest)
            rest)))
     ((if-form? expr)
      (error "make-induction-claim(find-app-forms): not supported"
             expr))
     (else '())))
  (define (prop form)
    (cond
     ((apply-rule '()
                  (rule vars
                        '()
                        (app-form (get-name f) vars)
                        c)
                  form
                  '())
      => identity)
     (else
      (error "make-induction-claim: fail" app-form))))
  (cond
   ((apply-function f vars)
    => (lambda (expr)
         (let build ((expr expr))
           (cond
            ((if-form? expr)
             (let ((app-forms (find-app-forms (if-form-test expr))))
               (implies/if (if (null? app-forms)
                               ''#t
                               (fold implies/if c (map prop app-forms)))
                           (if/if (if-form-test expr)
                                  (build (if-form-then expr))
                                  (build (if-form-else expr))))))
            (else
             (let ((app-forms (find-app-forms expr)))
               (fold implies/if c (map prop app-forms))))))))
   (else (error "make-induction-claim: invalid"
                f vars c))))

(define (add-proof/function sys f seed seq)
  (if seed
      (update-definition (make <total-function>
                           #:name (get-name f)
                           #:variables (get-variables f)
                           #:conditions (get-conditions f)
                           #:expression (get-expression f)
                           #:code (get-code f)
                           #:claim (make-totality-claim* sys seed f)
                           #:proof seq)
                         sys)
      (raise-exception
       (make-exception
        (make-exception-with-origin 'define-proof)
        (make-exception-with-message "need seed")
        (make-exception-with-irritants (get-expression f))))))

(define (add-proof/theorem sys t seed seq)
  (let ((claim
         (match seed
           ((fname . vars)
            (cond ((lookup fname sys)
                   => (cut make-induction-claim <> vars (get-expression t)))
                  (else (get-expression t))))
           (else (get-expression t)))))
    (update-definition (make <theorem>
                         #:name (get-name t)
                         #:variables (get-variables t)
                         #:expression (get-expression t)
                         #:claim claim
                         #:proof seq)
                       sys)))

(define (add-proof sys name seed seq)
  (cond
   ((not (sequence? seq))
    (raise-exception
     (make-exception
      (make-exception-with-origin 'define-proof)
      (make-exception-with-message "not sequence")
      (make-exception-with-irritants seq))))
   ((lookup name sys)
    => (lambda (def)
         (current-system
          (if (and (is-a? def <provable>)
                   (not (is-a? def <proved>)))
              (cond
               ((is-a? def <function>)
                (add-proof/function sys def seed seq))
               ((is-a? def <conjecture>)
                (add-proof/theorem sys def seed seq))
               (else
                (raise-exception
                 (make-exception
                  (make-exception-with-origin 'define-proof)
                  (make-exception-with-message "error")
                  (make-exception-with-irritants def)))))
              (raise-exception
               (make-exception
                (make-exception-with-origin 'define-proof)
                (make-exception-with-message "not provable definition")
                (make-exception-with-irritants def)))))))
   (else
    (raise-exception
     (make-exception
      (make-exception-with-origin 'define-proof)
      (make-exception-with-message "definition is not found")
      (make-exception-with-irritants name))))))

(define-syntax define-proof
  (syntax-rules ()
    ((_ name
        seed
        seq)
     (add-proof (current-system)
                'name
                'seed
                'seq))
    ((_ name seq)
     (define-proof name #f seq))))

(define (validate-expression sys name vars expr)
  (let* ((expr-fnames (expression-functions expr))
         (expr-vars (expression-vars expr))
         (expr-app-forms (expression-app-forms expr)))
    (define (err msg x)
      (raise-exception
       (make-exception
        (make-exception-with-origin name)
        (make-exception-with-message msg)
        (make-exception-with-irritants x))))
    (for-each (lambda (x)
                (when (member x expr-fnames)
                  (err "invalid variable" x)))
              vars)
    (for-each (lambda (fname)
                (unless (cond
                         ((lookup fname sys) =>
                          (lambda (f)
                            (for-each
                             (lambda (app-form)
                               (when (equal? fname (app-form-name app-form))
                                 (unless (= (length (get-variables f))
                                            (length (app-form-args app-form)))
                                   (err (format
                                         #f
                                         "~a :wrong number of arguments ~s"
                                         (get-name f)
                                         (get-variables f))
                                        (app-form-args app-form)))))
                             expr-app-forms)
                            #t))
                         (else #f))
                  (err "undefined function" fname)))
              expr-fnames)
    (for-each (lambda (x)
                (unless (member x vars)
                  (err "undefined variable" x)))
              expr-vars)))

(define (dup? xs)
  (if (null? xs)
      #f
      (if (member (car xs) (cdr xs))
          #t
          (dup? (cdr xs)))))

(define (validate-vars desc vars)
  (define (err)
    (raise-exception
     (make-exception
      (make-exception-with-message
       (string-append "(vikalpa) " desc ": duplicated variable"))
      (make-exception-with-irritants vars))))
  (when (dup? vars)
    (err)))

(define (recur? f)
  (member (get-name f)
          (expression-functions (get-expression f))))

(define (trivial-total? f sys)
  (and (not (recur? f))))

(define/guard (system-apropos (sys system?) (str string?))
  (filter (lambda (name)
            (string-match (string-append ".*"
                                         (regexp-quote str)
                                         ".*")
                          (symbol->string name)))
          (map get-name (get-definitions sys))))

(define (system-code sys)
  `(begin
     ,@(map (lambda (f)
              `(define (,(get-name f) ,@(get-variables f))
                 ,(code-expr (get-code f))))
            (reverse (filter (lambda (x)
                               (and (is-a? x <expandable-function>)
                                    (get-code x)))
                             (get-definitions sys))))))

(define (check sys)
  (let loop ((sys sys)
             (fails '()))
    (if (system-empty? sys)
        fails
        (let ((d (first-definition sys))
              (sys-without-first (remove-first-definition sys)))
          (define* (next #:optional fail)
            (loop sys-without-first
                  (if fail
                      (cons fail fails)
                      fails)))
          (cond
           ((is-a? d <proved>)
            (let ((result
                   (if (is-a? d <theorem>)
                       (rewrite sys-without-first
                                (get-claim d)
                                (get-proof d))
                       (rewrite sys
                                (get-claim d)
                                (get-proof d)))))
              (cond
               ((equal? result ''#t)
                (next))
               (else
                (next (list (get-name d) result))))))
           ((is-a? d <provable>)
            (next (list (get-name d))))
           (else (next)))))))

(define (system? x)
  (is-a? x <system>))

(define/guard (describe (sys system?) (name symbol?))
  (cond
   ((lookup name sys)
    => (lambda (def)
         (cond
          ((is-a? def <core-function>)
           `(define-core-function ,(get-name def) ,(get-variables def)))
          ((is-a? def <expandable-function>)
           `(define-function ,(get-name def) ,(get-variables def)
              ,(get-expression def)))
          ((is-a? def <axiom>)
           `(define-axiom ,(get-name def) ,(get-variables def)
              ,(get-expression def)))
          ((is-a? def <theorem*>)
           `(define-theorem ,(get-name def) ,(get-variables def)
              ,(get-expression def)))
          (((cut is-a? <> <macro>) def)
           `(define-syntax-rules ,(get-name def)))
          (else
           `(error 'fatal-error ,name)))))
   (else
    `(error 'not-found ,name))))

(define/guard (system-load (sys system?))
  (primitive-eval (system-code sys)))

;; (define/guard (system-environment (sys system?))
;;   (map (lambda (def)
;;          (list (get-name def)
;;                (show sys name)))
;;        (get-definitions sys)))

(define-system prelude ()
  (define-core-function not (x) not)
  (define-core-function equal? (x y) equal?)
  (define-core-function natural? (x) (lambda (x)
                                       (and (integer? x)
                                            (< 0 x))))
  (define-core-function < (x y) (natural? x) (natural? y) <)
  (define-core-function pair? (x) pair?)
  (define-core-function cons (x y) cons)
  (define-core-function car (x) (pair? x)
    (lambda (x) (if (pair? x) (car x) '())))
  (define-core-function cdr (x) (pair? x)
    (lambda (x) (if (pair? x) (cdr x) '())))
  (define-core-function + (x y)
    (lambda (x y)
      (if (number? x)
          (if (number? y)
              (+ x y)
              x)
          (if (number? y)
              y
              0))))
  (set-measure-predicate natural?)
  (set-measure-less-than <)
  (define-trivial-total-function list-induction (x)
    (if (not (pair? x))
        x
        (cons (car x)
              (list-induction (cdr x)))))
  (define-trivial-total-function size (x)
    (if (not (pair? x))
        0
        (+ 1
           (+ (size (car x))
              (size (cdr x))))))

  (define-syntax-rules and ()
    ((and) '#t)
    ((and x) x)
    ((and x . xs) (if x (and . xs) #f)))

  (define-syntax-rules or ()
    ((or) '#f)
    ((or x) x)
    ((or x . xs) (if x x (or . xs))))

  (define-syntax-rules cond (else)
    ((cond (else e)) e)
    ((cond (test then) . rest)
     (if test then (cond . rest))))

  (define-syntax-rules implies ()
    ((implies x y) (if x y #t))
    ((implies x y z . rest)
     (if x (implies y z . rest) #t)))
  
  (define-axiom if-nest (x y z)
    (if x
        (equal? (if x y z) y)
        (equal? (if x y z) z)))

  (define-axiom if-true (x y)
    (equal? (if '#t x y) x))

  (define-axiom if-false (x y)
    (equal? (if '#f x y) y))

  (define-axiom if-same (x y)
    (equal? (if x y y) y))

  (define-axiom if-not (x y z)
    (equal? (if (not x) y z)
            (if x z y)))

  (define-axiom equal-same (x)
    (equal? (equal? x x) '#t))

  (define-axiom equal-swap (x y)
    (equal? (equal? x y) (equal? y x)))

  (define-axiom equal-if (x y)
    (implies (equal? x y) (equal? x y)))
  
  (define-axiom pair/cons (x y)
    (equal? (pair? (cons x y)) '#t))

  (define-axiom cons/car+cdr (x)
    (implies (pair? x)
             (equal? (cons (car x) (cdr x)) x)))

  (define-axiom car/cons (x y)
    (equal? (car (cons x y)) x))

  (define-axiom cdr/cons (x y)
    (equal? (cdr (cons x y)) y))

  (define-axiom natural/size (x)
    (equal? (natural? (size x)) #t))

  (define-axiom size/car (x)
    (equal? (< (size (car x)) (size x)) #t))

  (define-axiom size/cdr (x)
    (equal? (< (size (cdr x)) (size x)) #t))

  (define-axiom equal-car (x1 y1 x2 y2)
    (implies (equal? (cons x1 y1) (cons x2 y2))
             (equal? x1 x2)))

  (define-theorem caar-cons2 (x y z)
    (equal? (car (car (cons (cons x y) z))) x))
  
  (define-function app (x y)
    (if (not (pair? x))
        y
        (cons (car x)
              (app (cdr x) y))))
  
  (define-theorem assoc-app (x y z)
    (equal? (app x (app y z))
            (app (app x y) z)))

  (define-proof caar-cons2
    (((1 1)  car/cons)
     ((1) car/cons)
     (() equal-same)))

  (define-proof app
    (size x)
    (((2 3) size/cdr)
     ((2) if-same)
     ((1) natural/size)
     (() if-true)))

  (define-proof assoc-app
    (list-induction x)
    ())
  )