;;; Vikalpa --- Prove S-expression
;;; Copyright © 2020 Masaya Tojo <masaya@tojo.tokyo>
;;;
;;; This file is part of Vikalpa.
;;;
;;; Vikalpa is free software; you can redistribute it and/or modify it
;;; under the terms of the GNU General Public License as published by
;;; the Free Software Foundation; either version 3 of the License, or
;;; (at your option) any later version.
;;;
;;; Vikalpa is distributed in the hope that it will be useful, but
;;; WITHOUT ANY WARRANTY; without even the implied warranty of
;;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
;;; General Public License for more details.
;;;
;;; You should have received a copy of the GNU General Public License
;;; along with Vikalpa.  If not, see <http://www.gnu.org/licenses/>.

(define-module (vikalpa)
  #:export (rewrite)
  #:use-module (vikalpa syntax)
  #:use-module (vikalpa primitive)
  #:use-module (ice-9 match)
  #:use-module (ice-9 format)
  #:use-module (ice-9 control)
  #:use-module ((srfi srfi-1) #:select (every any member lset-union fold))
  #:use-module (srfi srfi-8)
  #:use-module (srfi srfi-11)
  #:use-module (srfi srfi-26))

(define (debug f . args)
  (if #f
      (apply format #t f args)
      #t))

(define (option p?)
  (lambda (x)
    (or (p? x) (not x))))

(define (list-of p?)
  (lambda (x)
    (and (list? x)
         (every p? x))))

;; (expression? x) -> boolean?
(define (expression? expr)
  (cond ((expr-quoted? expr)
         (or (integer? (expr-unquote expr))
             (boolean? (expr-unquote expr))
             (symbol? (expr-unquote expr))))
        ((form? expr)
         (and (expression? (car expr))
              (list? (cdr expr))
              (every expression? (cdr expr))))
        ((variable? expr) #t)
        (else #f)))

(define (form? expr)
  (and (pair? expr)
       (not (eq? (car expr) 'quote))))

(define (form-name expr)
  (car expr))

(define (form-args expr)
  (cdr expr))

;; (define (expression-fold2 f fail acc expr1 expr2)
;;   (cond ((and (form? expr1)
;;               (form? expr2)
;;               (eq? (form-name expr1)
;;                    (form-name expr2)))
;;          (f (cons (form-name expr1)
;;                   (fold (lambda (x acc)
;;                           (expression-fold2 f fail <> <> acc))
;;                        (form-args expr1)
;;                        (form-args expr2)))))
;;         ((or (form? expr1)
;;              (form? expr2))
;;          (fail expr1 expr2 acc))
;;         (else (f expr1 expr2 acc))))

;; (define (expression-fold f acc expr)
;;   (cond ((form? expr)
;;          (f (cons (form-name expr)
;;                   (map (cut expression-fold f acc <>)
;;                        (form-args expr)))
;;             acc))
;;         (else (f expr acc))))

(define (expression-functions expr)
  (cond
   ((form? expr)
    (cons (form-name expr)
          (apply lset-union
                 eq?
                 (map expression-functions (form-args expr)))))
   (else '())))

(define (expression-vars expr)
  (cond
   ((form? expr)
    (apply lset-union eq?
           (map expression-vars (form-args expr))))
   ((variable? expr) (list expr))
   (else '())))

;; (expr-quoted? x) -> boolean?
(define (expr-quoted? expr)
  (and (pair? expr)
       (eq? 'quote (car expr))
       (pair? (cdr expr))
       ((const #t) (car (cdr expr)))
       (null? (cdr (cdr expr)))))

(define (expr-unquote expr)
  (car (cdr expr)))

;; (expr-quoted? x) -> boolean?
(define (expr-quote expr)
  (list 'quote expr))

;; (variable? x) -> boolean?
(define (variable? x)
  (symbol? x))

;; (variable=? variable? variable?) -> boolean?
(define (variable=? v1 v2)
  (eq? v1 v2))

;; (rule? x) -> boolean?
(define (rule? x)
  (and (list? x)
       (= 5 (length x))
       (eq? (car x) 'rule)
       (let ((vars (list-ref x 1)))
         (and (list? vars)
              (every variable? vars)))
       (let ((preconds (list-ref x 2)))
         (and (list? preconds)
              (every expression? preconds)))
       (expression? (list-ref x 3))
       (expression? (list-ref x 4))))

;; (rule (list-of variable?) expression? expression?) -> rule?
(define (rule vars preconds lhs rhs)
  (list 'rule vars preconds lhs rhs))

;; (rule-vars rule?) -> (list-of variable?)
(define (rule-vars r)
  (list-ref r 1))

;; (rule-preconds rule?) -> expression?
(define (rule-preconds r)
  (list-ref r 2))

;; (rule-lhs rule?) -> expression?
(define (rule-lhs r)
  (list-ref r 3))

;; (rule-rhs rule?) -> expression?
(define (rule-rhs r)
  (list-ref r 4))

;; (environment x) -> boolean?
;; environment is alist
(define (environment x)
  (cond ((null? x) #t)
        ((pair? x)
         (and (pair? (car x))
              (variable? (car (car x)))
              (expression? (cdr (car x)))
              (environment (cdr x))))
        (else #f)))


(define (match-expr f context acc preconds expr1 expr2 fail)
  (cond
   ((and (expr-quoted? expr1)
         (expr-quoted? expr2)
         (equal? expr1 expr2))
    (f (cons '(quoted) context) acc preconds expr1 expr2 fail))
   ((and (expr-if? expr1)
         (expr-if? expr2))
    (let*-values (((acc/test expr/test)
                   (match-expr f '(if 1)
                               acc
                               preconds
                               (expr-if-test expr1)
                               (expr-if-test expr2)
                               fail))
                  ((expr/then acc/then)
                   (match-expr f
                               (cons '(if 2) context)
                               acc/test
                               (cons (expr-if-test expr2) preconds)
                               (expr-if-then expr1)
                               (expr-if-then expr2)
                               fail))
                  ((acc/else expr/else)
                   (match-expr f
                               (cons '(if 3) context)
                               acc/then
                               (cons (expr-not (expr-if-test expr2))
                                     preconds)
                               (expr-if-else expr1)
                               (expr-if-else expr2)
                               fail)))
      (values acc/else (expr-if expr/test expr/then expr/else))))
   ((and (form? expr1)
         (form? expr2)
         (eq? (form-name expr1)
              (form-name expr2)))
    (let fold2 ((expr1-args (form-args expr1))
                (expr2-args (form-args expr2))
                (acc acc)
                (i 1))
      (cond ((and (null? expr1-args)
                  (null? expr2-args))
             (values acc '()))
            ((and (pair? expr1-args)
                  (pair? expr2-args))
             (receive (first-acc first-expr)
                 (match-expr f
                             (cons `(,(form-name expr1) ,i) context)
                             acc
                             preconds
                             (car expr1-args)
                             (car expr2-args)
                             fail)
               (receive (rest-acc rest-expr)
                   (fold2 (cdr expr1-args)
                          (cdr expr2-args)
                          first-acc
                          (+ i 1))
                 (values (cons first-expr rest-expr)
                         rest-acc))))
            (else
             (fail context acc)))))
   (else
    (fail context acc))))

;; (apply-rule preconds rule? expression?) -> (or (cons rhs environment) #f)
(define (apply-rule preconds rl expr env)
  (define (fail)
    (shift k #f))
  (define (var? v)
    (and (member v (rule-vars rl))
         #t))
  (define (add-env var expr env)
    (cond
     ((assoc var env)
      => (match-lambda
           ((env-var . env-expr)
            (if (equal? env-expr expr)
                env
                (fail)))))
     (else
      (cons (cons var expr)
            env))))
  (define (mat-map lhss exprs env)
    (cond ((and (pair? lhss)
                (pair? exprs))
           (mat-map (cdr lhss)
                    (cdr exprs)
                    (mat (car lhss)
                         (car exprs)
                         env)))
          ((and (null? lhss)
                (null? exprs))
           env)
          (else (fail))))
  (define (mat lhs expr env)
    (debug "lhs ~a, expr ~a, env ~a~%" lhs expr env)
    (cond ((expr-quoted? lhs)
           (if (expr-quoted? expr)
               (and (equal? lhs expr)
                    env)
               (fail)))
          ((form? lhs)
           (if (and (form? expr)
                    (symbol? (form-name lhs))
                    (eqv? (form-name lhs) (form-name expr)))
               (mat-map (form-args lhs) (form-args expr) env)
               (fail)))
          ((var? lhs) (add-env lhs expr env))
          (else (fail))))
  (define (mat-preconds rlps k+env)
    (if (null? rlps)
        k+env
        (mat-preconds (cdr rlps)
                      (any (lambda (p)
                             (shift k
                                    (cond
                                     ((reset (mat (car rlps) p (cdr k+env)))
                                      => (lambda (env) (k (cons k env))))
                                     (else (k #f)))))
                           preconds))))
  (define (substitute env expr)
    (cond ((expr-quoted? expr) expr)
          ((pair? expr)
           (cons (substitute env (car expr))
                 (substitute env (cdr expr))))
          ((var? expr)
           (cond ((assoc expr env) => cdr)
                 (else (fail))))
          (else expr)))
  (debug "rule: ~a~%" rl)
  (debug "preconds: ~a~%" preconds)
  (debug "expr: ~a~%" expr)
  (reset
   (shift k
          (match (mat-preconds (rule-preconds rl) (cons k env))
            ((k . env)
             (cond
              ((reset (mat (rule-lhs rl)
                           expr
                           env))
               => (cut substitute <> (rule-rhs rl)))
              (else
               (k #f))))
            (else #f)))))

;; (system? x) -> boolean?
;; system is alist
(define (system? x)
  (cond ((null? x) #t)
        ((pair? x)
         (and (pair? (car x))
              (or (proposition? (car x))
                  (primitive-function? (car x))
                  (macro? (car x))
                  (function? (car x)))
              (system? (cdr x))))
        (else #f)))

(define (primitive-function? x)
  (and (list? x)
       (= 4 (length x))
       (variable? (list-ref x 0))
       (eq? 'primitive-function (list-ref x 1))
       (let ((ps (list-ref x 2)))
         (and (list? ps)
              (every procedure? ps)))
       (procedure? (list-ref x 3))))

;; (primitive-function variable? (list-of procedure?) procedure?) -> primitive-function?
(define (primitive-function name ps proc)
  (list name 'primitive-function ps proc))

(define (primitive-function-name pf)
  (list-ref pf 0))

(define (primitive-function-preds pf)
  (list-ref pf 2))

(define (primitive-function-proc pf)
  (list-ref pf 3))

(define (match-primitive-function pf expression)
  (and (pair? expression)
       (eq? (primitive-function-name pf) (car expression))
       (list? (cdr expression))
       (every identity (map (lambda (pred expr)
                              (and (expr-quoted? expr)
                                   (pred (expr-unquote expr))))
                            (primitive-function-preds pf)
                            (cdr expression)))))

(define (apply-primitive-function pf expression)
  (apply (primitive-function-proc pf) (cdr expression)))

(define (function? x)
  (and (list? x)
       (= 4 (length x))
       (variable? (function-name x))
       (eq? 'function (list-ref x 1))
       (vars? (function-vars x))
       (expression? (function-expression x))))

;; (function variable? vars? expression?) -> function?
(define/guard (function (name variable?) (vars vars?) (expr expression?))
  (list name 'function vars expr))

(define (function-name f)
  (list-ref f 0))

(define (function-vars f)
  (list-ref f 2))

(define (function-expression f)
  (list-ref f 3))

(define (mrule? x)
  (and (list? x)
       (= 3 (length x))
       (eq? 'mrule (list-ref x 0))
       ((const #t) (mrule-lhs x))
       ((const #t) (mrule-rhs x))))

(define (mrule lhs rhs)
  (list 'mrule lhs rhs))

(define (mrule-vars mrl)
  (define (all-vars x)
    (cond ((expr-quoted? x) '())
          ((pair? x)
           (append (all-vars (car x))
                   (all-vars (cdr x))))
          ((variable? x) (list x))
          (else '())))
  (all-vars (mrule-lhs mrl)))

(define (mrule-lhs mrl)
  (list-ref mrl 1))

(define (mrule-rhs mrl)
  (list-ref mrl 2))

(define (macro? x)
  (and (list? x)
       (= 3 (length x))
       (eq? 'macro (list-ref x 1))
       (variable? (macro-name x))
       (let ((mrls (macro-mrules x)))
         (and (list? mrls)
              (every mrule? mrls)))))

(define (macro-name m)
  (list-ref m 0))

(define (macro-mrules m)
  (list-ref m 2))

(define (macro name rules)
  (list name 'macro rules))

(define (apply-mrule rl expr)
  (define (var? v)
    (and (member v (mrule-vars rl))
         #t))
  (call/cc
   (lambda (k)
     (define (mat-map lhs-tree expr-tree env)
       (cond ((and (pair? lhs-tree)
                   (pair? expr-tree))
              (mat-map (car lhs-tree)
                       (car expr-tree)
                       (mat-map (cdr lhs-tree)
                                (cdr expr-tree)
                                env)))
             (else (mat lhs-tree expr-tree env))))
     (define (mat lhs expr env)
       (cond ((expr-quoted? lhs)
              (if (expr-quoted? expr)
                  (and (equal? lhs expr)
                       env)
                  (k #f)))
             ((and (pair? lhs)
                   (pair? expr))
              (mat-map lhs expr env))
             ((var? lhs)
              (cond
               ((assoc lhs env)
                => (match-lambda
                     ((env-var . env-expr)
                      (if (equal? env-expr expr)
                          env
                          (k #f)))))
               (else
                (cons (cons lhs expr)
                      env))))
             ((eqv? lhs expr) env)
             (else (k #f))))
     (define (substitute env expr)
       (cond ((expr-quoted? expr) expr)
             ((pair? expr)
              (cons (substitute env (car expr))
                    (substitute env (cdr expr))))
             ((and (variable? expr) (assoc expr env)) => cdr)
             (else expr)))
     (substitute (mat (mrule-lhs rl)
                      expr
                      '())
                 (mrule-rhs rl)))))

(define (apply-macro m expr)
  (cond ((and (pair? expr)
              (eq? (macro-name m) (car expr)))
         (let loop ((rs (macro-mrules m)))
           (cond ((null? rs) expr)
                 ((apply-mrule (car rs) expr) => identity)
                 (else (loop (cdr rs))))))
        (else #f)))

(define/guard (expand (ms (list-of macro?)) (expr (const #t)))
  (let loop ((ms ms)
             (expr expr))
    (cond
     ((null? ms) expr)
     (else (expand (cdr ms)
                   (cond
                    ((apply-macro (car ms) expr) => identity)
                    (else expr)))))))

(define/guard (expand* (ms (list-of macro?)) (expr (const #t)))
  (let loop ((ms ms)
             (expr expr))
    (let ((new-expr (expand ms expr)))
      (if (equal? expr new-expr)
          (if (pair? new-expr)
              (cons (expand* ms (car new-expr))
                    (expand* ms (cdr new-expr)))
              new-expr)
          (expand* ms new-expr)))))

;; (axiom variable? vars? expression?) -> axiom?
;; axiom? is proposition
(define/guard (axiom (name variable?) (vars vars?) (expr expression?))
  (list name 'axiom vars expr))

(define (vars? x)
  (and (list? x)
       (every variable? x)))

;; (axiom? x) -> boolean?
(define (axiom? x)
  (and (list? x)
       (= 4 (length x))
       (variable?  (list-ref x 0))
       (eq? 'axiom (list-ref x 1))
       (vars? (list-ref x 2))
       (expression? (list-ref x 3))))

;; (theorem name vars? expression?) -> theorem?
(define/guard (theorem (name variable?) (vars vars?) (expr expression?))
  (list name 'theorem vars expr))

;; (theorem? x) -> boolean?
;; theorem? is proposition
(define (theorem? x)
  (and (list? x)
       (= 4 (length x))
       (variable? (list-ref x 0))
       (eq? 'theorem (list-ref x 1))
       (vars? (list-ref x 2))
       (expression? (list-ref x 3))))

(define (theorem-name x)
  (list-ref x 0))

;; (proposition? x) -> boolean?
(define (proposition? x)
  (or (axiom? x)
      (theorem? x)))

(define (proposition-name x)
  (list-ref x 0))

(define (proposition-vars x)
  (list-ref x 2))

(define (proposition-expression x)
  (list-ref x 3))

(define (proposition-rules x)
  (expression->rules (proposition-vars x)
                     '()
                     (proposition-expression x)))

;; (rewriter path? command?) -> rewriter?
(define (rewriter p c)
  (cons p c))

(define (rewriter-path r)
  (car r))

(define (rewriter-command r)
  (cdr r))

(define (rewriter? x)
  (and (pair? x)
       (path? (car x))
       (command? (cdr x))))

;; (sequence? x) -> boolean?
(define (sequence? x)
  (and (list? x)
       (every rewriter? x)))

;; (path? x) -> boolean?
;; path is list
(define (path? x)
  (and (list? x)
       (every natural? x)))

;; (command-name? x) -> booelan?
(define (command? x)
  (and (pair? x)
       (command-name? (car x))
       ((list-of command-option?) (cdr x))))

;; (command-name? x) -> booelan?
(define (command-name? x)
  (or (symbol? x)
      ((list-of symbol?) x)))

;; (command-option? x) -> boolean?
(define (command-option? x)
  (and (pair? x)
       (case (car x)
         ((set) (and (list? x)
                     (= 3 (length x))
                     (variable? (list-ref x 1))
                     (expression? (list-ref x 2))))
         (else #f))))

(define (command-name x)
  (car x))

(define (command-options x)
  (cdr x))

;; (extract path? expression? preconds? procedure?) -> (values expression? procedure?)
(define (extract path expr fail)
  (if (null? path)
      (values expr '() identity)
      (let ((i (car path)))
        (cond
         ((expr-if? expr)
          (let ((precond (expr-if-test expr)))
            (receive (extracted-expr extracted-preconds builder)
                (extract (cdr path) (list-ref expr i) fail)
              (values extracted-expr
                      (case i
                        ((1) '())
                        ((2) (cons precond extracted-preconds))
                        ((3) (cons (expr-not precond) extracted-preconds))
                        (else (fail "(if) invaild path" path)))
                      (lambda (x)
                        (append (list-head expr i)
                                (list (builder x))
                                (list-tail expr (+ i 1))))))))
         ((< i (length expr))
          (receive (extracted-expr preconds builder)
              (extract (cdr path) (list-ref expr i) fail)
            (values extracted-expr
                    preconds
                    (lambda (x)
                      (append (list-head expr i)
                              (list (builder x))
                              (list-tail expr (+ i 1)))))))
         (else
          (fail "invalid path" path))))))

(define (function->rules x)
  (list (rule (function-vars x)
              '()
              (cons (function-name x)
                    (function-vars x))
              (function-expression x))
        (rule (function-vars x)
              '()
              (function-expression x)
              (cons (function-name x)
                    (function-vars x)))))

(define (parse-options/prop ops)
  (if (null? ops)
      (values '())
      (receive (env)
          (parse-options/prop (cdr ops))
        (case (caar ops)
          ((set) (let ((op (car ops)))
                   (cons (cons (list-ref op 1)
                               (list-ref op 2))
                         env)))
          (else
           (error "invalid option:" (car ops)))))))

(define (rewrite/prop cmd b prop preconds expr fail)
  (receive (env)
      (parse-options/prop (command-options cmd))
    (cond
     ((any (cut apply-rule preconds <> expr env)
           (proposition-rules prop)) => identity)
     (else
      (fail (format #f "no match-rule (~a)" cmd))))))

;; (rewrite system? rewriter? expression? procedure?) -> expr
(define (rewrite1 b expr fail r)
  (let* ((cmd (rewriter-command r))
         (cmd/name (command-name cmd)))
    (debug "~%~%cmd: ~a~%" cmd)
    #;(format #t "~%~%cmd: ~a~%" cmd)
    (receive (extracted-expr preconds builder)
        (extract (rewriter-path r) expr fail)
      (builder
       (cond
        ((equal? cmd/name '(look))
         (format #t "~y" extracted-expr)
         (error "look"))
        ((equal? cmd/name '(expand))
         (expand (filter macro? b) extracted-expr))
        ((equal? cmd/name '(expand*))
         (expand* (filter macro? b) extracted-expr))
        ((and (symbol? cmd/name)
              (assoc cmd/name b))
         => (lambda (x)
              (cond
               ((proposition? x) (rewrite/prop cmd b x preconds extracted-expr fail))
               ((function? x)
                (cond
                 ((any (cut apply-rule '() <> extracted-expr '())
                       (function->rules x)) => identity)
                 (else
                  (fail (format #f "no match-function (~a)" cmd)))))
               ((primitive-function? x)
                (cond
                 ((match-primitive-function x extracted-expr)
                  (apply-primitive-function x extracted-expr))
                 (else
                  (fail "can't apply-primitive-function (~a)" cmd))))
               ((macro? x)
                (cond
                 ((apply-macro x extracted-expr) => identity)
                 (else
                  (fail "macro fail"))))
               (else
                (fail "rewrite error")))))
        (else (fail "no cmd (~a)" cmd)))))))

(define/guard (rewrite (b system?) (expr expression?) (seq sequence?))
  (let loop ((expr expr)
             (seq seq))
    (debug "~y~%" expr)
    #;(format #t "~y~%" expr)
    (if (null? seq)
        expr
        (loop (rewrite1 b
                        expr
                        (lambda (x . args)
                          (apply error
                                 (format #f "rewrite: ~a" x)
                                 args))
                        (car seq))
              (cdr seq)))))

(define (expr-not x)
  (list 'not x))

(define (expr-equal? x)
  (and (list? x)
       (= 3 (length x))
       (eq? 'equal? (list-ref x 0))
       (expression? (list-ref x 1))
       (expression? (list-ref x 2))))

(define (expr-equal-lhs x)
  (list-ref x 1))

(define (expr-equal-rhs x)
  (list-ref x 2))

(define (expr-if? x)
  (and (list? x)
       (= 4 (length x))
       (eq? 'if (list-ref x 0))
       (expression? (expr-if-test x))
       (expression? (expr-if-then x))
       (expression? (expr-if-else x))))

(define (expr-if x y z)
  (list 'if x y z))

(define (expr-if-test x)
  (list-ref x 1))

(define (expr-if-then x)
  (list-ref x 2))

(define (expr-if-else x)
  (list-ref x 3))

(define (expression->rules vars preconds expr)
  (if (expr-if? expr)
      (append (expression->rules vars
                                 (cons (expr-if-test expr) preconds)
                                 (expr-if-then expr))
              (expression->rules vars
                                 (cons (expr-not (expr-if-test expr)) preconds)
                                 (expr-if-else expr)))
      (if (expr-equal? expr)
          (list (rule vars
                      preconds
                      (expr-equal-lhs expr)
                      (expr-equal-rhs expr))
                (rule vars
                      preconds
                      (expr-equal-rhs expr)
                      (expr-equal-lhs expr)))
          '())))

(define (proposition->rules def)
  (expression->rules (proposition-vars def)
                     '()
                     (proposition-expression def)))

(define current-system (make-parameter '()))

(define (add-system x)
  (let ((b (current-system)))
    (current-system
     (cond ((assoc (proposition-name x) b)
            => (lambda (prop)
                 (if (equal? x prop)
                     b
                     (error "add-system: error"))))
           (else (cons x b))))))

(define-syntax define-axiom
  (syntax-rules ()
    ((_ name (var ...) expr)
     (add-system (axiom 'name '(var ...) 'expr)))))

(define-syntax define-theorem
  (syntax-rules ()
    ((_ name (var ...) expr)
     (add-system (theorem 'name '(var ...) 'expr)))))

(define-syntax define-function
  (syntax-rules ()
    ((_ name (var ...) expr)
     (let ((f (function 'name '(var ...) 'expr)))
       (add-system f)
       f))))

(define-syntax define-macro
  (syntax-rules ()
    ((_ name () ((lhs1 . lhs2) rhs) ...)
     (add-system (macro 'name
                 (list (mrule '(lhs1 . lhs2) 'rhs)
                       ...))))))

(define-syntax define-system
  (syntax-rules ()
    ((_ name (systems ...) expr ...)
     (define* (name #:optional (parent '()))
       (parameterize ([current-system ((compose systems ... identity) parent)])
         expr
         ...
         (unless (system? (current-system))
           (error "define-system: error"))
         (current-system))))))

(define (atom? x)
  (not (pair? x)))

(define-system prelude ()
  (define-axiom equal-same (x)
    (equal? (equal? x x) '#t))

  (define-axiom equal-swap (x y)
    (equal? (equal? x y) (equal? y x)))

  (define-axiom equal-if (x y)
    (if (equal? x y) (equal? x y) '#t))

  (define-axiom atom/cons (x y)
    (equal? (atom? (cons x y)) '#f))

  (define-axiom car/cons (x y)
    (equal? (car (cons x y)) x))

  (define-axiom cdr/cons (x y)
    (equal? (cdr (cons x y)) y))

  (define-axiom cons/car+cdr (x)
    (if (atom? x)
        '#t
        (equal? (cons (car x) (cdr x)) x)))

  (define-axiom if-nest (x y z)
    (if x
        (equal? (if x y z) y)
        (equal? (if x y z) z)))

  (define-axiom if-nest-t (x y z)
    (if x
        (equal? (if x y z) y)
        '#t))

  (define-axiom if-nest-f (x y z)
    (if x
        '#t
        (equal? (if x y z) z)))

  (define-axiom if-false (x y)
    (equal? (if '#f x y) y))

  (define-axiom if-same (x y)
    (equal? (if x y y) y))

  (define-axiom natural/size (x)
    (equal? (natural? (size x))
            '#t))

  (define-axiom size/car (x)
    (if (atom? x)
        '#t
        (equal? (< (size (car x)) (size x))
                '#t)))

  (define-axiom size/cdr (x)
    (if (atom? x)
        '#t
        (equal? (< (size (cdr x)) (size x))
                '#t)))

  (define-macro list ()
    ((list) '())
    ((list x . y) (cons x (list . y))))

  (define-macro + ()
    ((+) '0)
    ((+ x) x)
    ((+ x . xs) (b+ x (+ . xs))))

  (define-macro - ()
    ((- x) (u- x))
    ((- x . xs) (+ x . (u- (+ . xs)))))

  (define-macro and ()
    ((and) '#t)
    ((and x) x)
    ((and x . xs) (if x (and . xs) #f)))

  (define-macro or ()
    ((or) '#f)
    ((or x) x)
    ((or x . xs) (if x x (or . xs))))

  (define-axiom if-not (x y z)
    (equal? (if (not x)
                y
                z)
            (if x
                z
                y))))

(define (measure? x)
  (and (pair? x)
       (variable? (car x))
       (list? (cdr x))
       (<= 1 (length (cdr x)))))

(define (measure-function-name m)
  (car m))

(define (measure-function-vars m)
  (cdr m))

(define (subst lhs rhs expr)
  (apply-rule '()
              (rule (expression-vars lhs) '() lhs rhs)
              expr
              '()))

(define (function-form f)
  (cons (function-name f) (function-vars f)))

;; (define (make-totality-claim m f)
;;   (let ((vs (function-vars f))
;;         (fexpr (function-expression f)))
;;     (expression-fold (lambda (expr)
;;                        (cond
;;                         ((form? expr)
;;                          )))
;;                      (function-expression f))))

(define-system app/system (prelude)
  (define-function app (x y)
    (if (atom? x)
        y
        (cons (car x) (app (cdr x) y))))

  (define-theorem associate-app (x y z)
    (equal? (app (app x y) z)
            (app x (app y z))))

  #;
  (rewrite (app/system)
           '(if (natural? (size (app a b)))
                (if (atom? a)
                    '#t
                    (< (size (app (cdr a) b))
                       (size (app a b))))
                '#t)
           '(((2 3 2 1) app)
             ((2 3 2 1) if-nest)
             ((2 3 1 1) cdr/cons (set x (car a)))
             ((2 3) if-same (set x (atom? (cons (car a) (app (cdr a) b)))))
             ((2 3 3) size/cdr)
             ((2 3 1) atom/cons)
             ((2 3) if-false)
             ((2) if-same)
             (() if-same)))
  #;
  (rewrite (app/system)
           '(if (atom? a)
                (equal? (app (app a b) c)
                        (app a (app b c)))
                (if (equal? (app (app (cdr a) b) c)
                            (app (cdr a) (app b c)))
                    (equal? (app (app a b) c)
                            (app a (app b c)))
                    '#t))
           '(((2 2) app)
             ((2 2) if-nest-t)
             ((2 1 1) app)
             ((2 1 1) if-nest-t)
             ((2) equal-same)
             ((3 2 1 1) app)
             ((3 2 1 1) if-nest-f)
             ((3 2 2) app)
             ((3 2 2) if-nest-f)
             ((3 2 2 2) equal-if)
             ((3 2 1) app)
             ((3 2 1 3 1) car/cons)
             ((3 2 1 3 2 1) cdr/cons)
             ((3 2 1 1) atom/cons)
             ((3 2 1) if-false)
             ((3 2) equal-same)
             ((3) if-same)
             (() if-same)))
  )

(define (size x)
  (if (pair? x)
      (+ 1
         (size (car x))
         (size (cdr x)))
      0))

(define (app x y)
    (if (atom? x)
        y
        (cons (car x) (app (cdr x) y))))