app/build.gradle


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77

apply plugin: 'com.android.application'
apply from: 'copyLibs.gradle'    // enable 'copyLibs.gradle' script plugin
apply plugin: 'eclipse'

android {
    compileSdkVersion 23
    buildToolsVersion "23.0.2"
    defaultConfig {
        applicationId "com.zeapo.pwdstore"
        minSdkVersion 15
        targetSdkVersion 23
        versionCode 55
        versionName "1.2.0.35"
    }

    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_7
        targetCompatibility JavaVersion.VERSION_1_7
    }

    // avoid Travis failures
    lintOptions {
        abortOnError false
    }

    packagingOptions {
        exclude '.readme'
    }

    //
    // To sign release builds, create the file `gradle.properties` in
    // $HOME/.gradle or in your project directory with this content:
    //
    // mStoreFile=/path/to/key.store
    // mStorePassword=xxx
    // mKeyAlias=alias
    // mKeyPassword=xxx
    //
    if (project.hasProperty('mStoreFile') &&
            project.hasProperty('mStorePassword') &&
            project.hasProperty('mKeyAlias') &&
            project.hasProperty('mKeyPassword')) {
        signingConfigs {
            release {
                storeFile file(mStoreFile)
                    storePassword mStorePassword
                    keyAlias mKeyAlias
                    keyPassword mKeyPassword
            }
        }
        buildTypes.release.signingConfig = signingConfigs.release
    } else {
        buildTypes.release.signingConfig = null
    }

}

dependencies {
    compile 'com.android.support:appcompat-v7:23.1.1'
    compile 'com.android.support:recyclerview-v7:23.1.1'
    compile 'com.android.support:cardview-v7:23.1.1'
    compile 'com.android.support:design:23.1.1'
    compile 'org.sufficientlysecure:openpgp-api:9.0'
    compile ('org.eclipse.jgit:org.eclipse.jgit:3.7.1.201504261725-r') {
        exclude group: 'org.apache.httpcomponents', module: 'httpclient'
    }
    compile 'com.jcraft:jsch:0.1.53'
    compile 'org.apache.commons:commons-io:1.3.2'
    compile 'com.jayway.android.robotium:robotium-solo:5.3.1'
    compile 'net.rdrei.android.dirchooser:library:2.1@aar'
    compile group: 'com.google.guava', name: 'guava', version: '18.0'
}
tasks.findAll {    // make all tasks whose name starts with 'assemble'...
    it.name.startsWith 'assemble'
}.each {           // ... depending on 'copyDependenciesIntoLibs' task from 'copyLibs.gradle' script plugin
    it.dependsOn copyDependenciesIntoLibs
}